Implementacja CIEDE2000 w Ada

Ta strona przedstawia referencyjną implementację formuły różnicy kolorów CIEDE2000 w Ada. Jeśli chcesz zapewnić idealną kompatybilność (do dziesiątego miejsca po przecinku) z niektórymi implementacjami innych firm, może być konieczne zmodyfikowanie komentarzy w kodzie źródłowym. Aby to ułatwić, poniższy link automatyzuje tę operację.

Funkcja ΔE2000 w Ada

Rozważmy bardziej powszechne i akademickie (Sharma, 2005) z dwóch sformułowań.

-- This function written in Ada is not affiliated with the CIE (International Commission on Illumination),
-- and is released into the public domain. It is provided "as is" without any warranty, express or implied.

with Ada.Numerics.Generic_Elementary_Functions;

-- The classic CIE ΔE2000 implementation, which operates on two L*a*b* colors, and returns their difference.
-- "l" ranges from 0 to 100, while "a" and "b" are unbounded and commonly clamped to the range of -128 to 127.
function ciede_2000 (l_1, a_1, b_1, l_2, a_2, b_2 : Long_Float) return Long_Float is
	package Math is new Ada.Numerics.Generic_Elementary_Functions (Long_Float);
	-- Working in Ada 2005 with the CIEDE2000 color-difference formula.
	-- k_l, k_c, k_h are parametric factors to be adjusted according to
	-- different viewing parameters such as textures, backgrounds...
	k_l : constant Long_Float := 1.0;
	k_c : constant Long_Float := 1.0;
	k_h : constant Long_Float := 1.0;
	m_pi : constant Long_Float := Ada.Numerics.Pi;
	n, c_1, c_2, h_1, h_2, h_m, h_d, p, r_t, l, t, h, c: Long_Float;
begin
	n := (Math.Sqrt(a_1 * a_1 + b_1 * b_1) + Math.Sqrt(a_2 * a_2 + b_2 * b_2)) * 0.5;
	n := n * n * n * n * n * n * n;
	-- A factor involving chroma raised to the power of 7 designed to make
	-- the influence of chroma on the total color difference more accurate.
	n := 1.0 + 0.5 * (1.0 - Math.Sqrt(n / (n + 6103515625.0)));
	-- Application of the chroma correction factor.
	c_1 := Math.Sqrt(a_1 * a_1 * n * n + b_1 * b_1);
	c_2 := Math.Sqrt(a_2 * a_2 * n * n + b_2 * b_2);
	-- atan2 is preferred over atan because it accurately computes the angle of
	-- a point (x, y) in all quadrants, handling the signs of both coordinates.
	if (a_1 /= 0.0) or (b_1 /= 0.0) then
		h_1 := Math.Arctan(b_1, a_1 * n);
		if h_1 < 0.0 then h_1 := h_1 + 2.0 * m_pi; end if;
	else h_1 := 0.0; end if;
	if (a_2 /= 0.0) or (b_2 /= 0.0) then
		h_2 := Math.Arctan(b_2, a_2 * n);
		if h_2 < 0.0 then h_2 := h_2 + 2.0 * m_pi; end if;
	else h_2 := 0.0; end if;
	if h_1 < h_2 then n := h_2 - h_1; else n := h_1 - h_2; end if;
	-- Cross-implementation consistent rounding.
	if m_pi - 1.0E-14 < n and n < m_pi + 1.0E-14 then
		n := m_pi;
	end if;
	-- When the hue angles lie in different quadrants, the straightforward
	-- average can produce a mean that incorrectly suggests a hue angle in
	-- the wrong quadrant, the next lines handle this issue.
	h_m := (h_1 + h_2) * 0.5;
	h_d := (h_2 - h_1) * 0.5;
	if m_pi < n then
		h_d := h_d + m_pi;
		-- 📜 Sharma’s formulation doesn’t use the next line, but the one after it,
		-- and these two variants differ by ±0.0003 on the final color differences.
		h_m := h_m + m_pi;
		-- if h_m < m_pi then h_m := h_m + m_pi; else h_m := h_m - m_pi; end if;
	end if;
	p := 36.0 * h_m - 55.0 * m_pi;
	n := (c_1 + c_2) * 0.5;
	n := n * n * n * n * n * n * n;
	-- The hue rotation correction term is designed to account for the
	-- non-linear behavior of hue differences in the blue region.
	r_t := -2.0 *	Math.Sqrt(n / (n + 6103515625.0)) *
			Math.Sin(m_pi / 3.0 *
			Math.Exp(p * p / (-25.0 * m_pi * m_pi)));
	n := (l_1 + l_2) * 0.5;
	n := (n - 50.0) * (n - 50.0);
	-- Lightness.
	l := (l_2 - l_1) / (k_l * (1.0 + 0.015 * n / Math.Sqrt(20.0 + n)));
	-- These coefficients adjust the impact of different harmonic
	-- components on the hue difference calculation.
	t := 1.0 +	0.24 * Math.Sin(2.0 * h_m + m_pi / 2.0) +
			0.32 * Math.Sin(3.0 * h_m + 8.0 * m_pi / 15.0) -
			0.17 * Math.Sin(h_m + m_pi / 3.0) -
			0.20 * Math.Sin(4.0 * h_m + 3.0 * m_pi / 20.0);
	n := c_1 + c_2;
	-- Hue.
	h := 2.0 * Math.Sqrt(c_1 * c_2) *
			Math.Sin(h_d) / (k_h * (1.0 + 0.0075 * n * t));
	-- Chroma.
	c := (c_2 - c_1) / (k_c * (1.0 + 0.0225 * n));
	-- Returning the square root ensures that dE00 accurately reflects the
	-- geometric distance in color space, which can range from 0 to around 185.
	return Math.Sqrt(l * l + h * h + c * c + c * h * r_t);
end ciede_2000;

-- GitHub Project : https://github.com/michel-leonard/ciede2000-color-matching
--   Online Tests : https://michel-leonard.github.io/ciede2000-color-matching

-- L1 = 74.5   a1 = 47.9   b1 = 4.1
-- L2 = 74.8   a2 = 53.8   b2 = -4.2
-- CIE ΔE00 = 4.5097679907 (Bruce Lindbloom, Netflix’s VMAF, ...)
-- CIE ΔE00 = 4.5097525960 (Gaurav Sharma, OpenJDK, ...)
-- Deviation between implementations ≈ 1.5e-5

-- See the source code comments for easy switching between these two widely used ΔE*00 implementation variants.

Parametry k_l, k_c i k_h

Parametry k_l, k_c i k_h we wzorze CIEDE2000 to współczynniki wagowe stosowane odpowiednio do składowych jasności (ΔL*), chromu (ΔC*) i odcienia (ΔH*). Są one zdefiniowane jako stałe w kodzie źródłowym. W kodzie źródłowym są one zdefiniowane jako stałe z domyślną wartością 1, która odpowiada standardowym warunkom obserwacji określonym przez Międzynarodową Komisję Oświetlenia (CIE). W praktyce może być konieczne dostosowanie tych współczynników w celu odzwierciedlenia określonych warunków: na przykład k_l = 2 jest czasami używane, aby nadać większą wagę różnicom w jasności (powszechne zjawisko w przemyśle tekstylnym), podczas gdy k_c lub k_h można zmniejszyć, aby zwiększyć tolerancję na zmiany nasycenia lub odcienia. Podsumowując, współczynniki te wahają się zazwyczaj między 0,5 a 2, przy czym 1 jest wartością najczęściej spotykaną.

Dokładność i niezawodność kodu źródłowego

Różnica między akademickim sformułowaniem Sharmy a uproszczonym sformułowaniem Lindblooma nie przekracza ±0,0003 na końcowym ΔE2000. Przedstawiona tutaj implementacja jest 64-bitowa i zapewnia dokładność na ponad 10 miejsc po przecinku; wybór jednej z formuły zamiast drugiej jest zatem kwestią techniczną. Na górze strony można wybrać jedną z dwóch formuł; obecnie wyświetlana jest formuła uproszczona.

Jak można ustalić, czy dana implementacja CIEDE2000 jest typu akademickiego, czy uproszczonego?

• Dokładnie oceńcie ciede_2000(27.5, 24.6, 9.2, 15.7, 56.6, -18.5)
• Jeśli wynik wynosi 19.999944, jest to typ akademicki (jak Sharma, OpenJDK itp.)
• Jeśli wynik wynosi 20.000002, jest to typ uproszczony (jak Lindbloom, Netflix VMAF itp.)

Jak przekonwertować kolory RGB na L*a*b*?

Przejdź do strony AWK, C, Dart, Java, JavaScript, Kotlin, Lua, PHP, Python, Ruby lub Rust, gdzie taki konwerter (wykorzystujący iluminant D65) jest już zaimplementowany oprócz funkcji porównywania kolorów.

Zakresy wartości w CIELAB i interpretacja ΔE2000

W przestrzeni barw CIELAB składnik L* oznacza jasność i zwykle mieści się w zakresie od 0 (czarny) do 100 (biały). Składniki a* i b* opisują osie barw: a* przechodzi od zielonego do czerwonego, a b* od niebieskiego do żółtego. W praktyce wartości a* i b* prawie zawsze mieszczą się w przedziale od -128 do +127, chociaż norma nie określa oficjalnego ograniczenia dla tych dwóch składowych.

ΔE2000 (CIEDE2000) określa percepcyjną różnicę między dwoma kolorami: 0 oznacza identyczne kolory, a wyższe wartości (do 185 i więcej) wskazują na większą różnicę. Na przykład wartość ΔE2000 około 5 oznacza kolory podobne, natomiast około 15 oznacza kolory wyraźnie różne. Gdy wartość ΔE2000 przekracza 40, porównywane kolory nie mają już praktycznie nic wspólnego i nie można z nich wyciągnąć żadnych konkretnych wniosków.

Przykład zastosowania w Ada

-- Compute the Delta E (CIEDE2000) color difference between two L*a*b* colors in Ada

-- Color 1: l1 = 28.9, a1 = 47.5, b1 = 2.0
-- Color 2: l2 = 28.8, a2 = 41.6, b2 = -1.7

deltaE := ciede_2000(l1, a1, b1, l2, a2, b2);
Put(deltaE, Fore => 1, Aft => 15, Exp => 0);
New_Line;

-- .................................................. This shows a ΔE2000 of 2.7749016764
-- As explained in the comments, compliance with Gaurav Sharma would display 2.7749152801

Wyniki testów

Nasz program testowy, napisany w języku C99, zawiera 250 precyzyjnych testów statycznych. Wyniki pokazują, że ta funkcja CIEDE2000 w TypeScript jest interoperacyjna z 41 innymi językami programowania.

CIEDE2000 Verification Summary :
  First Verified Line : 27,-123,101,44,42.0000098,-99,70.204734814936884
             Duration : 37.68 s
            Successes : 10000000
               Errors : 0
      Average Delta E : 63.0868
    Average Deviation : 7.2e-15
    Maximum Deviation : 2.7e-13

Pliki do pobrania

Zachęcamy do korzystania z tych plików udostępnionych przez Michela, nawet w celach komercyjnych.

Społeczność

Co sądzisz o tym kodzie źródłowym lub CIEDE2000? Twoja opinia jest dla nas ważna! Księga gości zawiera już 9 wiadomości - w tym 1 w języku polskim. Zajrzyj i podziel się swoją opinią.