CIEDE2000 的 Perl 实现

本页介绍了 CIEDE2000 色差公式在 Perl 中的参考实现。为了确保与某些第三方实现完全兼容（精确到小数点后十位），可能需要修改源代码中的注释。以下链接可以帮助您自动执行此操作。

Perl 中的ΔE2000 函数

让我们考虑一下这两种表述中更常见 和 学术性的（Sharma，2005 年）的一种。

# 此 Perl 函数属于公共领域，
# 与 CIE（国际照明委员会）无关。

use strict;
use warnings;
use Math::Trig qw(pi);

# 经典实现，接受两种颜色 L*a*b* 并返回它们的差值 CIEDE2000。
# "L" 分量在 0 到 100 之间变化；"a" 和 "b" 理论上无界，通常被映射到 -128 到 127 之间。
sub ciede_2000 {
	# 下面是用 Perl 计算 CIEDE2000 色差公式的过程。
	# k_l、k_c 和 k_h 是可调的参数因子，
	# 可根据具体的可视化需求（如纹理、背景）进行调整。
	my ($l_1, $a_1, $b_1, $l_2, $a_2, $b_2) = @_;
	my ($k_l, $k_c, $k_h) = (1.0, 1.0, 1.0);
	my $n = (sqrt($a_1 * $a_1 + $b_1 * $b_1) + sqrt($a_2 * $a_2 + $b_2 * $b_2)) * 0.5;
	$n = $n * $n * $n * $n * $n * $n * $n;
	# 为更准确地考虑色度的影响，
	# 与平均色度相关的项被提升至七次方。
	$n = 1.0 + 0.5 * (1.0 - sqrt($n / ($n + 6103515625.0)));
	# 应用色度校正因子，以补偿其非线性特性。
	my $c_1 = sqrt($a_1 * $a_1 * $n * $n + $b_1 * $b_1);
	my $c_2 = sqrt($a_2 * $a_2 * $n * $n + $b_2 * $b_2);
	# 相比 atan，更优先使用 atan2 函数，因为它可以计算
	# 点 (x, y) 在所有象限中的角度，并考虑 x 与 y 的符号。
	my $h_1 = atan2($b_1, $a_1 * $n);
	my $h_2 = atan2($b_2, $a_2 * $n);
	$h_1 += 2.0 * pi if $h_1 < 0.0;
	$h_2 += 2.0 * pi if $h_2 < 0.0;
	$n = abs($h_2 - $h_1);
	# 避免分支逻辑依赖于编程语言的舍入模式（RoundingMode）。
	$n = pi if pi - 1E-14 < $n && $n < pi + 1E-14;
	# 当色相角位于不同象限时，
	# 简单的算术平均可能产生错误的角度，
	# 以下代码对这种角度偏差进行了修正。
	my $h_m = ($h_1 + $h_2) * 0.5;
	my $h_d = ($h_2 - $h_1) * 0.5;
	if (pi < $n) {
		$h_d += pi;
  		# 📜 根据Sharma的表述，不使用下一行，而是使用其后的一行。
		# 注：这两种变体在最终色差上的差异仅为 ±0.0003。
		$h_m += pi;
		# $h_m += ($h_m < pi) ? pi : -pi;
	}
	my $p = 36.0 * $h_m - 55.0 * pi;
	$n = ($c_1 + $c_2) * 0.5;
	$n = $n * $n * $n * $n * $n * $n * $n;
	# 色相旋转校正项用于调整算法的行为，
	# 尤其在比较蓝色区域时效果更明显。
	my $r_t = -2.0 * sqrt($n / ($n + 6103515625.0))
			* sin(pi / 3.0 * exp($p * $p / (-25.0 * pi * pi)));
	$n = ($l_1 + $l_2) * 0.5;
	$n = ($n - 50.0) * ($n - 50.0);
	# 明度。
	my $l = ($l_2 - $l_1) / ($k_l * (1.0 + 0.015 * $n / sqrt(20.0 + $n)));
	# 这些系数用于调节谐波分量
	# 在色相差计算中的影响。
	my $t = 1.0	+ 0.24 * sin(2.0 * $h_m + pi * 0.5)
			+ 0.32 * sin(3.0 * $h_m + 8.0 * pi / 15.0)
			- 0.17 * sin($h_m + pi / 3.0)
			- 0.20 * sin(4.0 * $h_m + 3.0 * pi / 20.0);
	$n = $c_1 + $c_2;
	# 色相。
	my $h = 2.0 * sqrt($c_1 * $c_2) * sin($h_d) / ($k_h * (1.0 + 0.0075 * $n * $t));
	# 色度。
	my $c = ($c_2 - $c_1) / ($k_c * (1.0 + 0.0225 * $n));
	# 返回平方根可确保 dE00 表示的是
	# CIELAB 空间中的几何距离（范围约为 0 到 185）。
	return sqrt($l * $l + $h * $h + $c * $c + $c * $h * $r_t);
}

#  GitHub 项目 : https://github.com/michel-leonard/ciede2000-color-matching
#      在线测试 : https://michel-leonard.github.io/ciede2000-color-matching

# L1 = 30.3   a1 = 46.0   b1 = 3.4
# L2 = 31.0   a2 = 40.9   b2 = -2.7
# CIE ΔE00 = 3.7301344547 (Bruce Lindbloom, Netflix’s VMAF, ...)
# CIE ΔE00 = 3.7301485713 (Gaurav Sharma, OpenJDK, ...)
# 不同实现之间的差异 ≈ 1.4e-5

# 请参阅源代码中的注释，以在这些 ΔE*00 实现变体之间进行切换。

k_l、k_c 与 k_h 参数

CIEDE2000 公式中的参数 k_l、k_c 和 k_h 是分别应用于亮度 (ΔL*) 、彩度 (ΔC*) 和色相 (ΔH*) 成分的加权系数。在源代码中，它们被定义为常数，默认值为 1，与国际照明委员会（CIE）规定的标准观测条件一致。在实践中，您可能需要调整这些系数以反映特定的条件：例如，k_l = 2 有时用于增加亮度差异的权重（这在纺织业中很常见），而 k_c 或 k_h 则可减小，以增加对饱和度或色调变化的容忍度。总而言之，这些系数通常在 0.5 到 2 之间变化，其中 1 是最常见的值。

源代码的准确性和可靠性

关于最终的ΔE2000，Sharma的学术形式与Lindblom的简化形式（本页默认显示）之间的差异不超过±0.0003。这种差异肉眼无法察觉，相当于两个32位实现之间的典型差异。本页所述的实现是64位的，并保证至少有10位正确的小数；因此，选择其中一种形式仅仅是技术细节上的差异。

✎ 如果您在比较中英文文本后发现任何不一致之处，请告知页面作者以便进行更正。

如何将 RGB 颜色转换为 L*a*b*？

请访问 AWK、 C、 Dart、 Java、 JavaScript、 Kotlin、 Lua、 PHP、 Python、 Ruby 或 Rust 页面，除了颜色比较功能外，这里已经实现了这种转换器（使用 D65 照明）。

CIELAB 中的数值范围和 ΔE2000 的解释

在 CIELAB 色彩空间中，L* 表示明度，通常在 0（黑色）到 100（白色）之间变化。a* 和 b* 成分代表颜色轴：a* 从绿色到红色，而 b* 从蓝色到黄色。实际上，a* 和 b* 的数值几乎总是限制在 -128 到 +127 之间，尽管标准并未对这两个分量规定正式的限制范围。

ΔE2000 （CIEDE2000）用于量化两种颜色的感知差异：0 表示完全相同，数值越大（最高可达185及以上）表示差异越明显。例如，ΔE2000 约为 5 表示颜色较接近，而约为 15 则表示颜色明显不同。当 ΔE2000 值超过 40 时，比较的颜色几乎没有任何共同之处；这就是测量能够可靠地告诉我们的全部信息。

Perl 中的使用示例

# Compute the Delta E (CIEDE2000) color difference between two L*a*b* colors in Perl

# Color 1: L1 = 97.9   a1 = 28.2   b1 = 3.0
# Color 2: L2 = 98.4   a2 = 22.0   b2 = -2.1

my $deltaE = ciede_2000($L1, $a1, $b1, $L2, $a2, $b2);
print $deltaE;

# .................................................. This shows a ΔE2000 of 4.4744286885
# As explained in the comments, compliance with Gaurav Sharma would display 4.4744462960

测试结果

我们的测试程序用 C99 编写，包含 250 个精确的静态测试。结果表明，这个用 TypeScript 编写的 CIEDE2000 函数可以与其他 41 种编程语言互操作。

CIEDE2000 Verification Summary :
  First Verified Line : 2,-126.1,-93.21,61.07,-94.6,65.5,70.390530131414
             Duration : 59.14 s
            Successes : 10000000
               Errors : 0
      Average Delta E : 62.9418
    Average Deviation : 4.5890806760207067e-14
    Maximum Deviation : 5.6843418860808015e-13

要下载的文件

请随意使用本方提供的这些文件，甚至用于商业目的。

社区

您认为此源代码或 CIEDE2000 如何？留言簿上已有 9 条留言，其中 1 条是中文留言。请看一看并分享您的意见。