This is a 5,086-byte text/plain file, placed in the public domain, which has been consulted 115 times since the year 2026.
# Limited Use License – March 1, 2025
# This source code is provided for public use under the following conditions :
# It may be downloaded, compiled, and executed, including in publicly accessible environments.
# Modification is strictly prohibited without the express written permission of the author.
# © Michel Leonard 2025
use strict;
use warnings;
use Math::Trig qw(pi);
# The classic CIE ΔE2000 implementation, which operates on two L*a*b* colors, and returns their difference.
# "l" ranges from 0 to 100, while "a" and "b" are unbounded and commonly clamped to the range of -128 to 127.
sub ciede_2000 {
# Working in Perl with the CIEDE2000 color-difference formula.
# k_l, k_c, k_h are parametric factors to be adjusted according to
# different viewing parameters such as textures, backgrounds...
my ($l_1, $a_1, $b_1, $l_2, $a_2, $b_2) = @_;
my ($k_l, $k_c, $k_h) = (1.0, 1.0, 1.0);
my $n = (sqrt($a_1 * $a_1 + $b_1 * $b_1) + sqrt($a_2 * $a_2 + $b_2 * $b_2)) * 0.5;
$n = $n * $n * $n * $n * $n * $n * $n;
# A factor involving chroma raised to the power of 7 designed to make
# the influence of chroma on the total color difference more accurate.
$n = 1.0 + 0.5 * (1.0 - sqrt($n / ($n + 6103515625.0)));
# Application of the chroma correction factor.
my $c_1 = sqrt($a_1 * $a_1 * $n * $n + $b_1 * $b_1);
my $c_2 = sqrt($a_2 * $a_2 * $n * $n + $b_2 * $b_2);
# atan2 is preferred over atan because it accurately computes the angle of
# a point (x, y) in all quadrants, handling the signs of both coordinates.
my $h_1 = atan2($b_1, $a_1 * $n);
my $h_2 = atan2($b_2, $a_2 * $n);
$h_1 += 2.0 * pi if $h_1 < 0.0;
$h_2 += 2.0 * pi if $h_2 < 0.0;
$n = abs($h_2 - $h_1);
# Cross-implementation consistent rounding.
$n = pi if pi - 1E-14 < $n && $n < pi + 1E-14;
# When the hue angles lie in different quadrants, the straightforward
# average can produce a mean that incorrectly suggests a hue angle in
# the wrong quadrant, the next lines handle this issue.
my $h_m = ($h_1 + $h_2) * 0.5;
my $h_d = ($h_2 - $h_1) * 0.5;
if (pi < $n) {
$h_d += pi;
# 📜 Sharma’s formulation doesn’t use the next line, but the one after it,
# and these two variants differ by ±0.0003 on the final color differences.
$h_m += pi;
# $h_m += ($h_m < pi) ? pi : -pi;
}
my $p = 36.0 * $h_m - 55.0 * pi;
$n = ($c_1 + $c_2) * 0.5;
$n = $n * $n * $n * $n * $n * $n * $n;
# The hue rotation correction term is designed to account for the
# non-linear behavior of hue differences in the blue region.
my $r_t = -2.0 * sqrt($n / ($n + 6103515625.0))
* sin(pi / 3.0 * exp($p * $p / (-25.0 * pi * pi)));
$n = ($l_1 + $l_2) * 0.5;
$n = ($n - 50.0) * ($n - 50.0);
# Lightness.
my $l = ($l_2 - $l_1) / ($k_l * (1.0 + 0.015 * $n / sqrt(20.0 + $n)));
# These coefficients adjust the impact of different harmonic
# components on the hue difference calculation.
my $t = 1.0 + 0.24 * sin(2.0 * $h_m + pi * 0.5)
+ 0.32 * sin(3.0 * $h_m + 8.0 * pi / 15.0)
- 0.17 * sin($h_m + pi / 3.0)
- 0.20 * sin(4.0 * $h_m + 3.0 * pi / 20.0);
$n = $c_1 + $c_2;
# Hue.
my $h = 2.0 * sqrt($c_1 * $c_2) * sin($h_d) / ($k_h * (1.0 + 0.0075 * $n * $t));
# Chroma.
my $c = ($c_2 - $c_1) / ($k_c * (1.0 + 0.0225 * $n));
# Returning the square root ensures that dE00 accurately reflects the
# geometric distance in color space, which can range from 0 to around 185.
return sqrt($l * $l + $h * $h + $c * $c + $c * $h * $r_t);
}
# GitHub Project : https://github.com/michel-leonard/ciede2000-color-matching
# Online Tests : https://michel-leonard.github.io/ciede2000-color-matching
# L1 = 55.2 a1 = 19.6 b1 = 5.5
# L2 = 57.1 a2 = 13.6 b2 = -2.9
# CIE ΔE00 = 7.1809662179 (Bruce Lindbloom, Netflix’s VMAF, ...)
# CIE ΔE00 = 7.1809797615 (Gaurav Sharma, OpenJDK, ...)
# Deviation between implementations ≈ 1.4e-5
# See the source code comments for easy switching between these two widely used ΔE*00 implementation variants.
#################################################
#################################################
############ ############
############ CIEDE2000 Driver ############
############ ############
#################################################
#################################################
# Reads a CSV file specified as the first command-line argument. For each line, this program
# in Perl displays the original line with the computed Delta E 2000 color difference appended.
# The C driver can offer CSV files to process and programmatically check the calculations performed there.
# Example of a CSV input line : 60.4,64,-25,63,100.2,17
# Corresponding output line : 60.4,64,-25,63,100.2,17,17.543537557735508722843996959283
die "Usage: perl ciede-2000-driver.pl <filename>\n" unless @ARGV == 1;
my $filename = $ARGV[0];
open my $fh, '<', $filename or die "Cannot open file '$filename': $!";
while (my $line = <$fh>) {
chomp $line;
my @vals = map { $_ + 0 } split /,/, $line;
my $result = ciede_2000(@vals);
print "$line,$result\n";
}
close $fh;