CIEDE2000 的 Ada 实现

本页面提供了一个用 Ada 编程语言编写的 CIEDE2000 色差公式的参考实现。为了确保与某些第三方实现完全兼容（精确到小数点后十位），可能需要修改源代码中的注释。以下链接可以帮助您自动执行此操作。

Ada 中的ΔE2000 函数

让我们考虑一下这两种表述中更常见 和 学术性的（Sharma，2005 年）的一种。

-- 此 Ada 函数属于公共领域，
-- 与 CIE（国际照明委员会）无关。

with Ada.Numerics.Generic_Elementary_Functions;

-- 经典实现，接受两种颜色 L*a*b* 并返回它们的差值 CIEDE2000。
-- "L" 分量在 0 到 100 之间变化；"a" 和 "b" 理论上无界，通常被映射到 -128 到 127 之间。
function ciede_2000 (l_1, a_1, b_1, l_2, a_2, b_2 : Long_Float) return Long_Float is
	package Math is new Ada.Numerics.Generic_Elementary_Functions (Long_Float);
	-- 下面是用 Ada 2005 计算 CIEDE2000 色差公式的过程。
	-- k_l、k_c 和 k_h 是可调的参数因子，
	-- 可根据具体的可视化需求（如纹理、背景）进行调整。
	k_l : constant Long_Float := 1.0;
	k_c : constant Long_Float := 1.0;
	k_h : constant Long_Float := 1.0;
	m_pi : constant Long_Float := Ada.Numerics.Pi;
	n, c_1, c_2, h_1, h_2, h_m, h_d, p, r_t, l, t, h, c: Long_Float;
begin
	n := (Math.Sqrt(a_1 * a_1 + b_1 * b_1) + Math.Sqrt(a_2 * a_2 + b_2 * b_2)) * 0.5;
	n := n * n * n * n * n * n * n;
	-- 为更准确地考虑色度的影响，
	-- 与平均色度相关的项被提升至七次方。
	n := 1.0 + 0.5 * (1.0 - Math.Sqrt(n / (n + 6103515625.0)));
	-- 应用色度校正因子，以补偿其非线性特性。
	c_1 := Math.Sqrt(a_1 * a_1 * n * n + b_1 * b_1);
	c_2 := Math.Sqrt(a_2 * a_2 * n * n + b_2 * b_2);
	-- 相比 atan，更优先使用 atan2 函数，因为它可以计算
	-- 点 (x, y) 在所有象限中的角度，并考虑 x 与 y 的符号。
	if (a_1 /= 0.0) or (b_1 /= 0.0) then
		h_1 := Math.Arctan(b_1, a_1 * n);
		if h_1 < 0.0 then h_1 := h_1 + 2.0 * m_pi; end if;
	else h_1 := 0.0; end if;
	if (a_2 /= 0.0) or (b_2 /= 0.0) then
		h_2 := Math.Arctan(b_2, a_2 * n);
		if h_2 < 0.0 then h_2 := h_2 + 2.0 * m_pi; end if;
	else h_2 := 0.0; end if;
	if h_1 < h_2 then n := h_2 - h_1; else n := h_1 - h_2; end if;
	-- 避免分支逻辑依赖于编程语言的舍入模式（RoundingMode）。
	if m_pi - 1.0E-14 < n and n < m_pi + 1.0E-14 then
		n := m_pi;
	end if;
	-- 当色相角位于不同象限时，
	-- 简单的算术平均可能产生错误的角度，
	-- 以下代码对这种角度偏差进行了修正。
	h_m := (h_1 + h_2) * 0.5;
	h_d := (h_2 - h_1) * 0.5;
	if m_pi < n then
		h_d := h_d + m_pi;
		-- 📜 根据Sharma的表述，不使用下一行，而是使用其后的一行。
		-- 注：这两种变体在最终色差上的差异仅为 ±0.0003。
		h_m := h_m + m_pi;
		-- if h_m < m_pi then h_m := h_m + m_pi; else h_m := h_m - m_pi; end if;
	end if;
	p := 36.0 * h_m - 55.0 * m_pi;
	n := (c_1 + c_2) * 0.5;
	n := n * n * n * n * n * n * n;
	-- 色相旋转校正项用于调整算法的行为，
	-- 尤其在比较蓝色区域时效果更明显。
	r_t := -2.0 *	Math.Sqrt(n / (n + 6103515625.0)) *
			Math.Sin(m_pi / 3.0 *
			Math.Exp(p * p / (-25.0 * m_pi * m_pi)));
	n := (l_1 + l_2) * 0.5;
	n := (n - 50.0) * (n - 50.0);
	-- 明度。
	l := (l_2 - l_1) / (k_l * (1.0 + 0.015 * n / Math.Sqrt(20.0 + n)));
	-- 这些系数用于调节谐波分量
	-- 在色相差计算中的影响。
	t := 1.0 +	0.24 * Math.Sin(2.0 * h_m + m_pi / 2.0) +
			0.32 * Math.Sin(3.0 * h_m + 8.0 * m_pi / 15.0) -
			0.17 * Math.Sin(h_m + m_pi / 3.0) -
			0.20 * Math.Sin(4.0 * h_m + 3.0 * m_pi / 20.0);
	n := c_1 + c_2;
	-- 色相。
	h := 2.0 * Math.Sqrt(c_1 * c_2) *
			Math.Sin(h_d) / (k_h * (1.0 + 0.0075 * n * t));
	-- 色度。
	c := (c_2 - c_1) / (k_c * (1.0 + 0.0225 * n));
	-- 返回平方根可确保 dE00 表示的是
	-- CIELAB 空间中的几何距离（范围约为 0 到 185）。
	return Math.Sqrt(l * l + h * h + c * c + c * h * r_t);
end ciede_2000;

--  GitHub 项目 : https://github.com/michel-leonard/ciede2000-color-matching
--      在线测试 : https://michel-leonard.github.io/ciede2000-color-matching

-- L1 = 74.5   a1 = 47.9   b1 = 4.1
-- L2 = 74.8   a2 = 53.8   b2 = -4.2
-- CIE ΔE00 = 4.5097679907 (Bruce Lindbloom, Netflix’s VMAF, ...)
-- CIE ΔE00 = 4.5097525960 (Gaurav Sharma, OpenJDK, ...)
-- 不同实现之间的差异 ≈ 1.5e-5

-- 请参阅源代码中的注释，以在这些 ΔE*00 实现变体之间进行切换。

k_l、k_c 与 k_h 参数

CIEDE2000 公式中的参数 k_l、k_c 和 k_h 是分别应用于亮度 (ΔL*) 、彩度 (ΔC*) 和色相 (ΔH*) 成分的加权系数。在源代码中，它们被定义为常数，默认值为 1，与国际照明委员会（CIE）规定的标准观测条件一致。在实践中，您可能需要调整这些系数以反映特定的条件：例如，k_l = 2 有时用于增加亮度差异的权重（这在纺织业中很常见），而 k_c 或 k_h 则可减小，以增加对饱和度或色调变化的容忍度。总而言之，这些系数通常在 0.5 到 2 之间变化，其中 1 是最常见的值。

源代码的准确性和可靠性

关于最终的ΔE2000，Sharma的学术形式与Lindblom的简化形式（本页默认显示）之间的差异不超过±0.0003。此处介绍的实现是64位版本，并保证精度超过10位小数；因此，选择其中一种形式仅仅是技术细节上的差异。在页面顶部，您可以在这两种表述之间进行选择；当前显示的是简化表述。

如何判断某个CIEDE2000的实现是学术型还是简化型？

• 计算 ciede_2000(56.6, 43.6, 41.1, 68.4, 9.4, -8.6) 的值
• 如果结果是 30.0001，则为学术型（例如 Sharma、OpenJDK 等）
• 如果结果是 29.9999，则为简体型（例如 Lindbloom、Netflix VMAF等）

如何将 RGB 颜色转换为 L*a*b*？

请访问 AWK、 C、 Dart、 Java、 JavaScript、 Kotlin、 Lua、 PHP、 Python、 Ruby 或 Rust 页面，除了颜色比较功能外，这里已经实现了这种转换器（使用 D65 照明）。

CIELAB 中的数值范围和 ΔE2000 的解释

在 CIELAB 色彩空间中，L* 表示明度，通常在 0（黑色）到 100（白色）之间变化。a* 和 b* 成分代表颜色轴：a* 从绿色到红色，而 b* 从蓝色到黄色。实际上，a* 和 b* 的数值几乎总是限制在 -128 到 +127 之间，尽管标准并未对这两个分量规定正式的限制范围。

ΔE2000 （CIEDE2000）用于量化两种颜色的感知差异：0 表示完全相同，数值越大（最高可达185及以上）表示差异越明显。例如，ΔE2000 约为 5 表示颜色较接近，而约为 15 则表示颜色明显不同。当 ΔE2000 值超过 40 时，比较的颜色几乎没有任何共同之处；这就是测量能够可靠地告诉我们的全部信息。

Ada 中的使用示例

-- Compute the Delta E (CIEDE2000) color difference between two L*a*b* colors in Ada

-- Color 1: l1 = 28.9, a1 = 47.5, b1 = 2.0
-- Color 2: l2 = 28.8, a2 = 41.6, b2 = -1.7

deltaE := ciede_2000(l1, a1, b1, l2, a2, b2);
Put(deltaE, Fore => 1, Aft => 15, Exp => 0);
New_Line;

-- .................................................. This shows a ΔE2000 of 2.7749016764
-- As explained in the comments, compliance with Gaurav Sharma would display 2.7749152801

测试结果

我们的测试程序用 C99 编写，包含 250 个精确的静态测试。这些测试可确保您的计算即使在关键的极限情况下也能准确无误，例如当反正切函数返回数学上未定义的值时。结果表明，该 Ada 版 CIEDE2000 函数与我们提供的 41 种其他编程语言兼容。

CIEDE2000 Verification Summary :
  First Verified Line : 27,-123,101,44,42.0000098,-99,70.204734814936884
             Duration : 37.68 s
            Successes : 10000000
               Errors : 0
      Average Delta E : 63.0868
    Average Deviation : 7.2e-15
    Maximum Deviation : 2.7e-13

要下载的文件

请随意使用本方提供的这些文件，甚至用于商业目的。

社区

您认为此源代码或 CIEDE2000 如何？留言簿上已有 9 条留言，其中 1 条是中文留言。请看一看并分享您的意见。