CIEDE2000 的 Prolog 实现

本页介绍了 CIEDE2000 色差公式在 Prolog 中的参考实现。为了确保与某些第三方实现完全兼容（精确到小数点后十位），可能需要修改源代码中的注释。以下链接可以帮助您自动执行此操作。

Prolog 中的ΔE2000 函数

让我们考虑一下这两种表述中更常见 和 学术性的（Sharma，2005 年）的一种。

% 此 Prolog 函数属于公共领域，
% 与 CIE（国际照明委员会）无关。

% 经典实现，接受两种颜色 L*a*b* 并返回它们的差值 CIEDE2000。
% "L" 分量在 0 到 100 之间变化；"a" 和 "b" 理论上无界，通常被映射到 -128 到 127 之间。
ciede_2000(L1, A1, B1, L2, A2, B2, DeltaE2000) :-
	% 下面是用 Prolog 计算 CIEDE2000 色差公式的过程。
	% K_L、K_C 和 K_H 是可调的参数因子，
	% 可根据具体的可视化需求（如纹理、背景）进行调整。
	K_L is 1.0,
	K_C is 1.0,
	K_H is 1.0,
	Pi_1 is 3.14159265358979323846,
	Pi_3 is 1.04719755119659774615,

	% 1. 计算初始色度（a* 和 b* 分量的范数）
	A1_sq is A1 * A1,
	B1_sq is B1 * B1,
	C_orig_1 is sqrt(A1_sq + B1_sq),
	A2_sq is A2 * A2,
	B2_sq is B2 * B2,
	C_orig_2 is sqrt(A2_sq + B2_sq),

	% 2. 计算平均色度及感知补偿因子 G
	C_avg is 0.5 * (C_orig_1 + C_orig_2),
	C_avg_3 is C_avg * C_avg * C_avg,
	C_avg_7 is C_avg_3 * C_avg_3 * C_avg,
	G_denom is C_avg_7 + 6103515625.0,
	G_ratio is C_avg_7 / G_denom,
	G_sqrt is sqrt(G_ratio),
	G_factor is 1.0 + 0.5 * (1.0 - G_sqrt),

	% 3. 对 a* 分量应用 G 修正，并计算修正后的色度 C’
	A1_prime is A1 * G_factor,
	C1_prime_sq is A1_prime * A1_prime + B1 * B1,
	C1_prime is sqrt(C1_prime_sq),
	A2_prime is A2 * G_factor,
	C2_prime_sq is A2_prime * A2_prime + B2 * B2,
	C2_prime is sqrt(C2_prime_sq),

	% 4. 计算色相角（弧度）并归一化到 [0, 2π[
	H1_raw is atan2(B1, A1_prime),
	H2_raw is atan2(B2, A2_prime),
	(H1_raw < 0.0 -> H1_adj is H1_raw + 2.0 * Pi_1 ; H1_adj = H1_raw),
	(H2_raw < 0.0 -> H2_adj is H2_raw + 2.0 * Pi_1 ; H2_adj = H2_raw),
	Delta_h is abs(H1_adj - H2_adj),
	H_mean_raw is 0.5 * (H1_adj + H2_adj),
	H_diff_raw is 0.5 * (H2_adj - H1_adj),

	% 检测色相均值跨越角度不连续性（π）
	Wrap_dist is abs(Pi_1 - Delta_h),
	(1.0e-14 < Wrap_dist, Pi_1 < Delta_h -> Hue_wrap = 1.0 ; Hue_wrap = 0),
	H_diff is H_diff_raw + Hue_wrap * Pi_1,
	% 📜 根据Sharma的表述，不使用下一行，而是使用其后的三行。
	% 注：这两种变体在最终色差上的差异仅为 ±0.0003。
	H_mean is H_mean_raw + Hue_wrap * Pi_1,
	% (Hue_wrap =:= 1, H_mean_raw < Pi_1 -> H_mean_hi = Pi_1 ; H_mean_hi = 0.0),
	% (Hue_wrap =:= 1, H_mean_hi =:= 0.0 -> H_mean_lo = Pi_1 ; H_mean_lo = 0.0),
	% H_mean is H_mean_raw + H_mean_hi - H_mean_lo,

	% 5. 计算色相–色度交互修正因子 R_T
	C_bar is 0.5 * (C1_prime + C2_prime),
	C_bar_3 is C_bar * C_bar * C_bar,
	C_bar_7 is C_bar_3 * C_bar_3 * C_bar,
	Rc_denom is C_bar_7 + 6103515625.0,
	R_C is sqrt(C_bar_7 / Rc_denom),
	Theta is 36.0 * H_mean - 55.0 * Pi_1,
	Theta_denom is -25.0 * Pi_1 * Pi_1,
	Exp_argument is Theta * Theta / Theta_denom,
	Exp_term is exp(Exp_argument),
	Delta_theta is Pi_3 * Exp_term,
	Sin_term is sin(Delta_theta),

	% 色度差与色相差的交互项
	R_T is -2.0 * R_C * Sin_term,

	% 6. 计算明度项（L* 通道）
	L_avg is 0.5 * (L1 + L2),
	L_delta_sq is (L_avg - 50.0) * (L_avg - 50.0),
	L_delta is L2 - L1,

	% 适应明度感知的非线性（因子 S_L）
	S_l_num is 0.015 * L_delta_sq,
	S_l_denom is sqrt(20.0 + L_delta_sq),
	S_L is 1.0 + S_l_num / S_l_denom,
	L_term is L_delta / (K_L * S_L),

	% 7. 计算依赖于色相的三角项及因子 T
	Trig_1 is 0.17 * sin(H_mean + Pi_3),
	Trig_2 is 0.24 * sin(2.0 * H_mean + 0.5 * Pi_1),
	Trig_3 is 0.32 * sin(3.0 * H_mean + 1.6  * Pi_3),
	Trig_4 is  0.2 * sin(4.0 * H_mean + 0.15 * Pi_1),
	T is 1.0 - Trig_1 + Trig_2 + Trig_3 - Trig_4,
	C_sum is C1_prime + C2_prime,
	C_product is C1_prime * C2_prime,
	C_geo_mean is sqrt(C_product),

	% 8. 计算色相差及缩放因子 S_H
	Sin_h_diff is sin(H_diff),
	S_H is 1.0 + 0.0075 * C_sum * T,
	H_term is 2.0 * C_geo_mean * Sin_h_diff / (K_H * S_H),

	% 9. 计算色度差及缩放因子 S_C
	C_delta is C2_prime - C1_prime,
	S_C is 1.0 + 0.0225 * C_sum,
	C_term is C_delta / (K_C * S_C),

	% 10. 将明度、色度、色相及交互项组合计算 ΔE₀₀
	L_part is L_term * L_term,
	C_part is C_term * C_term,
	H_part is H_term * H_term,
	Interaction is C_term * H_term * R_T,
	Delta_e_squared is L_part + C_part + H_part + Interaction,
	DeltaE2000 is sqrt(Delta_e_squared).

%  GitHub 项目 : https://github.com/michel-leonard/ciede2000-color-matching
%      在线测试 : https://michel-leonard.github.io/ciede2000-color-matching

% L1 = 14.8   a1 = 33.5   b1 = 2.4
% L2 = 16.6   a2 = 38.1   b2 = -2.7
% CIE ΔE00 = 3.6462011992 (Bruce Lindbloom, Netflix’s VMAF, ...)
% CIE ΔE00 = 3.6461873926 (Gaurav Sharma, OpenJDK, ...)
% 不同实现之间的差异 ≈ 1.4e-5

% 请参阅源代码中的注释，以在这些 ΔE*00 实现变体之间进行切换。

K_L、K_C 与 K_H 参数

CIEDE2000 公式中的参数 K_L、K_C 和 K_H 是分别应用于亮度 (ΔL*) 、彩度 (ΔC*) 和色相 (ΔH*) 成分的加权系数。在源代码中，它们被定义为常数，默认值为 1，与国际照明委员会（CIE）规定的标准观测条件一致。在实践中，您可能需要调整这些系数以反映特定的条件：例如，K_L = 2 有时用于增加亮度差异的权重（这在纺织业中很常见），而 K_C 或 K_H 则可减小，以增加对饱和度或色调变化的容忍度。总而言之，这些系数通常在 0.5 到 2 之间变化，其中 1 是最常见的值。

源代码的准确性和可靠性

在最终的 ΔE2000 上，夏尔马的学术表述与林德布卢姆的简化表述之间的差异不超过 ±0.0003。这相当于通常测量的两个 32 位实现之间的差异，人眼无法察觉。我们的 64 位计算公式彼此一致，都能保证至少 10 位正确的小数位数，因此选择一种计算公式还是其他计算公式只是一个技术细节。本页中的默认公式是社区中最常使用的公式。

✎ 如果您发现源代码中的注释与英文注释不一致，请通知页面作者，以便更正。

如何将 RGB 颜色转换为 L*a*b*？

请访问 AWK、 C、 Dart、 Java、 JavaScript、 Kotlin、 Lua、 PHP、 Python、 Ruby 或 Rust 页面，除了颜色比较功能外，这里已经实现了这种转换器（使用 D65 照明）。

CIELAB 中的数值范围和 ΔE2000 的解释

在 CIELAB 色彩空间中，L* 表示明度，通常在 0（黑色）到 100（白色）之间变化。a* 和 b* 成分代表颜色轴：a* 从绿色到红色，而 b* 从蓝色到黄色。实际上，a* 和 b* 的数值几乎总是限制在 -128 到 +127 之间，尽管标准并未对这两个分量规定正式的限制范围。

ΔE2000 （CIEDE2000）用于量化两种颜色的感知差异：0 表示完全相同，数值越大（最高可达185及以上）表示差异越明显。例如，ΔE2000 约为 5 表示颜色较接近，而约为 15 则表示颜色明显不同。当 ΔE2000 值超过 40 时，比较的颜色几乎没有任何共同之处；这就是测量能够可靠地告诉我们的全部信息。

Prolog 中的使用示例

% Compute the Delta E (CIEDE2000) color difference between two L*a*b* colors in Prolog

color_1([69.5, 43.6, -1.8]).
color_2([70.2, 37.9, 1.6]).

extract_lab([L, A, B], L, A, B).

compute_delta_e :-
	color_1(C1),
	color_2(C2),
	extract_lab(C1, L1, A1, B1),
	extract_lab(C2, L2, A2, B2),
	ciede_2000(L1, A1, B1, L2, A2, B2, DeltaE),
	format('Delta E 2000 = ~10f~n', [DeltaE]).

% .................................................. This shows a ΔE2000 of 2.8044781137
% As explained in the comments, compliance with Gaurav Sharma would display 2.8044649638

测试结果

我们的测试程序用 C99 编写，包含 250 个精确的静态测试。结果表明，这个用 TypeScript 编写的 CIEDE2000 函数可以与其他 41 种编程语言互操作。

CIEDE2000 Verification Summary :
  First Verified Line : 27,-123,101,44,-30,122,29.98937281745311
             Duration : 254.09 s
            Successes : 10000000
               Errors : 0
      Average Delta E : 63.2072
    Average Deviation : 5.0e-15
    Maximum Deviation : 1.1e-13

要下载的文件

请随意使用本方提供的这些文件，甚至用于商业目的。

社区

您认为此源代码或 CIEDE2000 如何？留言簿上已有 9 条留言，其中 1 条是中文留言。请看一看并分享您的意见。