CIEDE2000 的 Elixir 实现

本页展示了 Elixir 语言的 CIEDE2000 色差公式参考实现。如果您希望获得与第三方实现的精确匹配（精确到小数点后 10 位），可能需要对源代码进行一些修改，特别是通过注释和取消注释几行，这些修改可以通过下面的链接自动应用。

Elixir 中的ΔE2000 函数

让我们考虑一下这两种表述中更常见 和 学术性的（Sharma，2005 年）的一种。

# 此 Elixir 函数属于公共领域，
# 与 CIE（国际照明委员会）无关。

# 经典实现，接受两种颜色 L*a*b* 并返回它们的差值 CIEDE2000。
# "L" 分量在 0 到 100 之间变化；"a" 和 "b" 理论上无界，通常被映射到 -128 到 127 之间。
def ciede_2000(l_1, a_1, b_1, l_2, a_2, b_2)
	when is_float(l_1) and is_float(a_1)  and is_float(b_1) and is_float(l_2) and is_float(a_2)  and is_float(b_2) do
	# 下面是用 Elixir 计算 CIEDE2000 色差公式的过程。
	# k_l、k_c 和 k_h 是可调的参数因子，
	# 可根据具体的可视化需求（如纹理、背景）进行调整。
	{k_l, k_c, k_h, m_pi} = {1.0, 1.0, 1.0, :math.pi()}
	n = (:math.sqrt(a_1 * a_1 + b_1 * b_1) + :math.sqrt(a_2 * a_2 + b_2 * b_2)) * 0.5
	n = n * n * n * n * n * n * n
	# 为更准确地考虑色度的影响，
	# 与平均色度相关的项被提升至七次方。
	n = 1.0 + 0.5 * (1.0 - :math.sqrt(n / (n + 6103515625.0)))
	# 应用色度校正因子，以补偿其非线性特性。
	c_1 = :math.sqrt(a_1 * a_1 * n * n + b_1 * b_1)
	c_2 = :math.sqrt(a_2 * a_2 * n * n + b_2 * b_2)
	# 相比 atan，更优先使用 atan2 函数，因为它可以计算
	# 点 (x, y) 在所有象限中的角度，并考虑 x 与 y 的符号。
	h_1 = :math.atan2(b_1, a_1 * n)
	h_2 = :math.atan2(b_2, a_2 * n)
	h_1 = if h_1 < 0.0, do: h_1 + 2.0 * m_pi, else: h_1
	h_2 = if h_2 < 0.0, do: h_2 + 2.0 * m_pi, else: h_2
	n = abs(h_2 - h_1)
	# 避免分支逻辑依赖于编程语言的舍入模式（RoundingMode）。
	n = if m_pi - 1.0E-14 < n and n < m_pi + 1.0E-14, do: m_pi, else: n
	# 当色相角位于不同象限时，
	# 简单的算术平均可能产生错误的角度，
	# 以下代码对这种角度偏差进行了修正。
	h_m = (h_1 + h_2) * 0.5
	h_d = (h_2 - h_1) * 0.5
	h_d = if m_pi < n, do: h_d + m_pi, else: h_d
	# 📜 根据Sharma的表述，不使用下一行，而是使用其后的一行。
	# 注：这两种变体在最终色差上的差异仅为 ±0.0003。
	h_m = if m_pi < n, do: h_m + m_pi, else: h_m
	# h_m = if m_pi < n, do: (if h_m < m_pi, do: h_m + m_pi, else: h_m - m_pi), else: h_m
	p = 36.0 * h_m - 55.0 * m_pi
	n = (c_1 + c_2) * 0.5
	n = n * n * n * n * n * n * n
	# 色相旋转校正项用于调整算法的行为，
	# 尤其在比较蓝色区域时效果更明显。
	r_t = -2.0 * :math.sqrt(n / (n + 6103515625.0)) *
		:math.sin(m_pi / 3.0 * :math.exp(p * p / (-25.0 * m_pi * m_pi)))
	n = (l_1 + l_2) * 0.5
	n = (n - 50.0) * (n - 50.0)
	# 明度。
	l = (l_2 - l_1) / (k_l * (1.0 + 0.015 * n / :math.sqrt(20.0 + n)))
	# 这些系数用于调节谐波分量
	# 在色相差计算中的影响。
	t = 1.0 +	0.24 * :math.sin(2.0 * h_m + m_pi / 2.0) +
			0.32 * :math.sin(3.0 * h_m + 8.0 * m_pi / 15.0) -
			0.17 * :math.sin(h_m + m_pi / 3.0) -
			0.20 * :math.sin(4.0 * h_m + 3.0 * m_pi / 20.0)
	n = c_1 + c_2
	# 色相。
	h = 2.0 * :math.sqrt(c_1 * c_2) * :math.sin(h_d) / (k_h * (1.0 + 0.0075 * n * t))
	# 色度。
	c = (c_2 - c_1) / (k_c * (1.0 + 0.0225 * n))
	# 返回平方根可确保 dE00 表示的是
	# CIELAB 空间中的几何距离（范围约为 0 到 185）。
	:math.sqrt(l * l + h * h + c * c + c * h * r_t)
end

#  GitHub 项目 : https://github.com/michel-leonard/ciede2000-color-matching
#      在线测试 : https://michel-leonard.github.io/ciede2000-color-matching

# L1 = 80.1   a1 = 20.9   b1 = 4.3
# L2 = 82.2   a2 = 26.1   b2 = -3.9
# CIE ΔE00 = 6.1587582595 (Bruce Lindbloom, Netflix’s VMAF, ...)
# CIE ΔE00 = 6.1587450086 (Gaurav Sharma, OpenJDK, ...)
# 不同实现之间的差异 ≈ 1.3e-5

# 请参阅源代码中的注释，以在这些 ΔE*00 实现变体之间进行切换。

源代码的准确性和可靠性

Sharma 和 Lindbloom 公式之间的差异在最终 ΔE2000 上从未超过 ±0.0003，这相当于两个 32 位实现之间的通常差异，肉眼无法察觉。我们的 64 位实现相互一致，并保证至少正确到小数点后 10 位，因此选择使用哪种公式取决于所需的互操作性。本页介绍的默认公式是最常用的公式（它的微观优势是基于社区，矢量化稍显容易）。

✎ 如果您在源代码中发现与其他语言不对应的注释，请通知网站作者，他将研究您的建议并将其纳入源代码。

如何将 RGB 颜色转换为 L*a*b*？

请访问 AWK、 C、 Dart、 Java、 JavaScript、 Kotlin、 Lua、 PHP、 Python、 Ruby 或 Rust 页面，除了颜色比较功能外，这里已经实现了这种转换器（使用 D65 照明）。

CIELAB 中的数值范围和 ΔE2000 的解释

在 CIELAB 色彩空间中，L* 表示明度，通常在 0（黑色）到 100（白色）之间变化。a* 和 b* 则表示颜色轴：a* 从绿色到红色，b* 从蓝色到黄色。实际应用中，a* 和 b* 的数值一般在 -128 到 +127 之间，但在颜色转换时可能会略微超出该范围。

ΔE2000（CIEDE2000）用于量化两种颜色的感知差异：0 表示完全相同，数值越大（在极端情况下可达约 185）表示差异越明显。例如，ΔE2000 约为 5 表示颜色较接近，而约为 15 则表示颜色明显不同。

Elixir 中的使用示例

# Compute the Delta E (CIEDE2000) color difference between two L*a*b* colors in Elixir

{ l1, a1, b1 } = { 57.1, 17.1, 4.9  }
{ l2, a2, b2 } = { 59.2, 10.9, -3.1 }

delta_e = ciede_2000(l1, a1, b1, l2, a2, b2)
IO.puts("#{delta_e}")

# .................................................. This shows a ΔE2000 of 7.5254510508
# As explained in the comments, compliance with Gaurav Sharma would display 7.5254660817

测试结果

用 C99 语言编写的驱动程序经过 250 次精确的静态测试，证明该 Elixir 函数与其他编程语言中的 CIEDE2000 函数具有互操作性。

CIEDE2000 Verification Summary :
  First Verified Line : 27,-123,101,44,-30,122,29.989372817453113
             Duration : 157.82 s
            Successes : 10000000
               Errors : 0
      Average Delta E : 63.2072
    Average Deviation : 3.9e-15
    Maximum Deviation : 1.1e-13

要下载的文件

请随意使用本方提供的这些文件，甚至用于商业目的。

社区

如果您想就本 Elixir 源代码或 CIEDE2000 的总体情况发表意见，留言簿中已有 1 条中文留言，总共有 9 条留言，请告诉我们您的想法。