Implémentation de CIEDE2000 en F#

Cette page présente une implémentation de référence de la formule de différence de couleur CIEDE2000 en F#. Si vous souhaitez obtenir une correspondance exacte avec des implémentations tierces jusqu’à 10 décimales, vous pourriez avoir à apporter des modifications au code source, notamment en commentant et décommentant quelques lignes, ce qui peut être appliqué automatiquement via le lien suivant.

La fonction ΔE2000 en F#

Considérons la plus courante et académique (Sharma, 2005) des deux formulations.

// Cette fonction écrite en F# est placée dans le domaine public et
// n’est pas affiliée à la CIE (Commission Internationale de l’Éclairage).

open System

// L’implémentation CIEDE2000 classique qui accepte deux couleurs L*a*b* et renvoie leur différence.
// La composante "L" varie de 0 à 100. "a" et "b", non bornées, sont souvent projetées entre -128 et 127.
let ciede_2000 (l_1: float) (a_1: float) (b_1: float) (l_2: float) (a_2: float) (b_2: float) : float =
    // Traite la formule de différence de couleurs CIEDE2000 en F#.
    // k_l, k_c et k_h sont des facteurs paramétriques qu’on ajuste
    // selon des recommandations propres au secteur industriel.
    let k_l = 1.0
    let k_c = 1.0
    let k_h = 1.0
    let mutable n = (Math.Sqrt(a_1 * a_1 + b_1 * b_1) + Math.Sqrt(a_2 * a_2 + b_2 * b_2)) * 0.5
    n <- n * n * n * n * n * n * n
    // Un facteur impliquant la chroma moyenne à la puissance 7,
    // conçu pour modéliser plus précisément son influence.
    n <- 1.0 + 0.5 * (1.0 - Math.Sqrt(n / (n + 6103515625.0)))
    // Application du facteur de correction de la chroma pour compenser sa non-linéarité.
    let c_1 = Math.Sqrt(a_1 * a_1 * n * n + b_1 * b_1)
    let c_2 = Math.Sqrt(a_2 * a_2 * n * n + b_2 * b_2)
    // La fonction atan2 est préférée à atan car elle calcule l’angle d’un
    // point (x, y) dans tous les quadrants, en tenant compte du signe de x et y.
    let mutable h_1 = Math.Atan2(b_1, a_1 * n)
    let mutable h_2 = Math.Atan2(b_2, a_2 * n)
    if h_1 < 0.0 then h_1 <- h_1 + 2.0 * Math.PI
    if h_2 < 0.0 then h_2 <- h_2 + 2.0 * Math.PI
    n <- Math.Abs(h_2 - h_1)
    // Prévient le branchement de dépendre du RoundingMode du langage de programmation.
    if Math.PI - 1E-14 < n && n < Math.PI + 1E-14 then n <- Math.PI
    // Lorsque les angles de teinte sont dans différents quadrants,
    // la moyenne arithmétique simple peut donner un angle incorrect,
    // les lignes suivantes prennent en compte cette correction angulaire.
    let mutable h_m = (h_1 + h_2) * 0.5
    let mutable h_d = (h_2 - h_1) * 0.5
    if Math.PI < n then
        h_d <- h_d + Math.PI
        // 📜 La formulation de Sharma n’utilise pas la ligne suivante, mais plutôt celle d’après.
        // Note : ces deux variantes ne diffèrent que de ±0,0003 sur la différence de couleur finale.
        h_m <- h_m + Math.PI
        // h_m <- h_m + (if h_m < Math.PI then Math.PI else -Math.PI)
    let p = 36.0 * h_m - 55.0 * Math.PI
    n <- (c_1 + c_2) * 0.5
    n <- n * n * n * n * n * n * n
    // Le terme de correction de la rotation de teinte ajuste le comportement
    // de l’algorithme, d’autant plus si la comparaison porte sur des teintes bleues.
    let r_t = -2.0 * Math.Sqrt(n / (n + 6103515625.0))
                        * Math.Sin(Math.PI / 3.0 * Math.Exp(p * p / (-25.0 * Math.PI * Math.PI)))
    n <- (l_1 + l_2) * 0.5
    n <- (n - 50.0) * (n - 50.0)
    // Luminosité.
    let l = (l_2 - l_1) / (k_l * (1.0 + 0.015 * n / Math.Sqrt(20.0 + n)))
    // Ces coefficients modulent l’influence des composantes
    // harmoniques dans le calcul de la différence de teinte.
    let t = 1.0     + 0.24 * Math.Sin(2.0 * h_m + Math.PI / 2.0)
                    + 0.32 * Math.Sin(3.0 * h_m + 8.0 * Math.PI / 15.0)
                    - 0.17 * Math.Sin(h_m + Math.PI / 3.0)
                    - 0.20 * Math.Sin(4.0 * h_m + 3.0 * Math.PI / 20.0)
    n <- c_1 + c_2
    // Teinte.
    let h = 2.0 * Math.Sqrt(c_1 * c_2) * Math.Sin(h_d) / (k_h * (1.0 + 0.0075 * n * t))
    // Chroma.
    let c = (c_2 - c_1) / (k_c * (1.0 + 0.0225 * n))
    // Retourner la racine carrée assure que dE00 représente une distance
    // géométrique (comprise entre 0 et environ 185) dans l’espace CIELAB.
    Math.Sqrt(l * l + h * h + c * c + c * h * r_t)

//    Projet GitHub : https://github.com/michel-leonard/ciede2000-color-matching
//   Tests en ligne : https://michel-leonard.github.io/ciede2000-color-matching

// L1 = 79.1   a1 = 50.5   b1 = 2.2
// L2 = 78.5   a2 = 44.8   b2 = -1.9
// CIE ΔE00 = 2.8082542128 (Bruce Lindbloom, Netflix’s VMAF, ...)
// CIE ΔE00 = 2.8082675897 (Gaurav Sharma, OpenJDK, ...)
// Écart entre les implémentations ≈ 1.3e-5

// Voir les commentaires du code source pour passer d’une de ces variantes d’implémentation de ΔE*00 à l’autre.

Précision et fiabilité du code source

La différence entre les formulations de Sharma et Lindbloom ne dépasse jamais ±0,0003 sur le ΔE2000 final, ce qui correspond à l’écart habituel mesuré entre deux implémentations 32 bits et est imperceptible à l’œil humain. Nos implémentations 64 bits, toutes cohérentes entre elles, garantissent au moins 10 décimales correctes, de sorte que le choix d’une formulation plutôt qu’une autre dépend surtout de l’interopérabilité souhaitée. La formulation qui apparait par défaut sur cette page est la plus couramment utilisée (son micro-avantage réside dans son ancrage communautaire et dans sa légèreté supérieure à celle de son analogue lorsque vectorisée).

✎ Si vous trouvez dans le code source un commentaire qui ne correspond pas à une autre langue, veuillez en informer l’auteur du site, qui étudiera votre suggestion et l’intégrera dans le code source.

Comment convertir les couleurs RGB en L*a*b* ?

Rendez-vous sur la page AWK, C, Dart, Java, JavaScript, Kotlin, Lua, PHP, Python, Ruby ou Rust où un tel convertisseur (utilisant l’illuminant D65) est déjà implémenté en plus de la fonction de comparaison de couleurs.

Plages de valeurs dans CIELAB et interprétation du ΔE2000

Dans l’espace colorimétrique CIELAB, la composante L* représente la luminosité et varie de 0 (noir) à 100 (blanc). Les composantes a* et b* décrivent les axes de couleur : a* s’étend du vert au rouge, tandis que b* va du bleu au jaune. Dans la pratique, les valeurs de a* et b* se situent dans la plage -128 à +127, même si elles peuvent légèrement dépasser ces limites selon les conversions colorimétriques.

Le ΔE2000 (CIEDE2000) quantifie la différence perceptuelle entre deux couleurs : 0 signifie deux couleurs identiques, et des valeurs plus élevées (jusqu’à environ 185 dans les cas extrêmes) indiquent une différence plus marquée. Par exemple, une valeur ΔE2000 autour de 5 correspond à des couleurs proches, tandis qu’une valeur autour de 15 correspond à des couleurs clairement distinctes.

Exemple d’utilisation en F#

// Compute the Delta E (CIEDE2000) color difference between two L*a*b* colors in F#

let l1, a1, b1 = 3.9, 16.9, -4.9
let l2, a2, b2 = 3.1, 11.8, 3.6

let deltaE = ciede_2000 l1 a1 b1 l2 a2 b2
printfn "%f" deltaE

// .................................................. This shows a ΔE2000 of 7.0799401968
// As explained in the comments, compliance with Gaurav Sharma would display 7.0799265161

Résultats des tests

Le driver écrit en langage C99, doté de 250 tests statiques précis, a prouvé que cette fonction F# est interopérable avec la fonction CIEDE2000 mise à disposition dans les autres langages de programmation.

CIEDE2000 Verification Summary :
  First Verified Line : 73.2,-34,-46,97.09,38.44,-65,39.669742389892633
             Duration : 51.98 s
            Successes : 10000000
               Errors : 0
      Average Delta E : 62.9404
    Average Deviation : 4.2576547981676426e-15
    Maximum Deviation : 1.1368683772161603e-13

Fichiers à télécharger

Utilisez librement ces fichiers mis à disposition par Michel, même à des fins commerciales.

Communauté

Si vous souhaitez laisser votre avis sur ce code source F# ou sur CIEDE2000 en général, le livre d’or contient déjà 1 messages en français, et 9 messages au total, alors laissez-nous savoir ce que vous pensez.