Implémentation de CIEDE2000 en TCL

Cette page présente une implémentation de référence de la formule de différence de couleur CIEDE2000 en TCL. Si vous souhaitez obtenir une correspondance exacte avec des implémentations tierces jusqu’à 10 décimales, vous pourriez avoir à apporter des modifications au code source, notamment en commentant et décommentant quelques lignes, ce qui peut être appliqué automatiquement via le lien suivant.

La fonction ΔE2000 en TCL

Considérons la plus courante et académique (Sharma, 2005) des deux formulations.

# Cette fonction écrite en TCL est placée dans le domaine public et
# n’est pas affiliée à la CIE (Commission Internationale de l’Éclairage).

# L’implémentation CIEDE2000 classique qui accepte deux couleurs L*a*b* et renvoie leur différence.
# La composante "L" varie de 0 à 100. "a" et "b", non bornées, sont souvent projetées entre -128 et 127.
proc ciede_2000 { l_1 a_1 b_1 l_2 a_2 b_2 } {
	# Traite la formule de différence de couleurs CIEDE2000 en TCL.
	# k_l, k_c et k_h sont des facteurs paramétriques qu’on ajuste
	# selon des recommandations propres au secteur industriel.
	set k_l 1.0
	set k_c 1.0
	set k_h 1.0
	set pi 3.14159265358979323846264338328
	set n [expr { (sqrt($a_1 * $a_1 + $b_1 * $b_1) + sqrt($a_2 * $a_2 + $b_2 * $b_2)) * 0.5 }]
	set n [expr { $n * $n * $n * $n * $n * $n * $n }]
	# Un facteur impliquant la chroma moyenne à la puissance 7,
	# conçu pour modéliser plus précisément son influence.
	set n [expr { 1.0 + 0.5 * (1.0 - sqrt($n / ($n + 6103515625.0))) }]
	# Application du facteur de correction de la chroma pour compenser sa non-linéarité.
	set c_1 [expr { sqrt($a_1 * $a_1 * $n * $n + $b_1 * $b_1) }]
	set c_2 [expr { sqrt($a_2 * $a_2 * $n * $n + $b_2 * $b_2) }]
	# La fonction atan2 est préférée à atan car elle calcule l’angle d’un
	# point (x, y) dans tous les quadrants, en tenant compte du signe de x et y.
	set h_1 [expr { atan2($b_1, $a_1 * $n) }]
	set h_2 [expr { atan2($b_2, $a_2 * $n) }]
	if { $h_1 < 0.0 } { set h_1 [expr { $h_1 + 2.0 * $pi }] }
	if { $h_2 < 0.0 } { set h_2 [expr { $h_2 + 2.0 * $pi }] }
	set n [expr { abs($h_2 - $h_1) }]
	# Prévient le branchement de dépendre du RoundingMode du langage de programmation.
	if { $pi - 1E-14 < $n && $n < $pi + 1E-14 } {
		set n $pi
	}
	# Lorsque les angles de teinte sont dans différents quadrants,
	# la moyenne arithmétique simple peut donner un angle incorrect,
	# les lignes suivantes prennent en compte cette correction angulaire.
	set h_m [expr { ($h_1 + $h_2) * 0.5 }]
	set h_d [expr { ($h_2 - $h_1) * 0.5 }]
	if { $pi < $n } {
		set h_d [expr { $h_d + $pi }]
  		# 📜 La formulation de Sharma n’utilise pas la ligne suivante, mais plutôt celle d’après.
		# Note : ces deux variantes ne diffèrent que de ±0,0003 sur la différence de couleur finale.
		set h_m [expr { $h_m + $pi }]
  		# set h_m [expr {$h_m + ($h_m < $pi ? $pi : -$pi)}]
	}
	set p [expr { 36.0 * $h_m - 55.0 * $pi }]
	set n [expr { ($c_1 + $c_2) * 0.5 }]
	set n [expr { $n * $n * $n * $n * $n * $n * $n }]
	# Le terme de correction de la rotation de teinte ajuste le comportement
	# de l’algorithme, d’autant plus si la comparaison porte sur des teintes bleues.
	set r_t [expr { -2.0 * sqrt($n / ($n + 6103515625.0))
				* sin($pi / 3.0 * exp($p * $p / (-25.0 * $pi * $pi))) }]
	set n [expr { ($l_1 + $l_2) * 0.5 }]
	set n [expr { ($n - 50.0) * ($n - 50.0) }]
	# Luminosité.
	set l [expr { ($l_2 - $l_1) / ($k_l * (1.0 + 0.015 * $n / sqrt(20.0 + $n))) }]
	# Ces coefficients modulent l’influence des composantes
	# harmoniques dans le calcul de la différence de teinte.
	set t [expr { 1.0	+ 0.24 * sin(2.0 * $h_m + $pi * 0.5)
						+ 0.32 * sin(3.0 * $h_m + 8.0 * $pi / 15.0)
						- 0.17 * sin($h_m + $pi / 3.0)
						- 0.20 * sin(4.0 * $h_m + 3.0 * $pi / 20.0) }]
	set n [expr { $c_1 + $c_2 }]
	# Teinte.
	set h [expr { 2.0 * sqrt($c_1 * $c_2) * sin($h_d) / ($k_h * (1.0 + 0.0075 * $n * $t)) }]
	# Chroma.
	set c [expr { ($c_2 - $c_1) / ($k_c * (1.0 + 0.0225 * $n)) }]
	# Retourner la racine carrée assure que dE00 représente une distance
	# géométrique (comprise entre 0 et environ 185) dans l’espace CIELAB.
	return [expr { sqrt($l * $l + $h * $h + $c * $c + $c * $h * $r_t) }]
}

#    Projet GitHub : https://github.com/michel-leonard/ciede2000-color-matching
#   Tests en ligne : https://michel-leonard.github.io/ciede2000-color-matching

# L1 = 12.0   a1 = 25.9   b1 = -4.3
# L2 = 13.7   a2 = 20.0   b2 = 4.4
# CIE ΔE00 = 6.5762883529 (Bruce Lindbloom, Netflix’s VMAF, ...)
# CIE ΔE00 = 6.5762728956 (Gaurav Sharma, OpenJDK, ...)
# Écart entre les implémentations ≈ 1.5e-5

# Voir les commentaires du code source pour passer d’une de ces variantes d’implémentation de ΔE*00 à l’autre.

Précision et fiabilité du code source

La différence entre les formulations de Sharma et Lindbloom ne dépasse jamais ±0,0003 sur le ΔE2000 final, ce qui correspond à l’écart habituel mesuré entre deux implémentations 32 bits et est imperceptible à l’œil humain. Nos implémentations 64 bits, toutes cohérentes entre elles, garantissent au moins 10 décimales correctes, de sorte que le choix d’une formulation plutôt qu’une autre dépend surtout de l’interopérabilité souhaitée. La formulation qui apparait par défaut sur cette page est la plus couramment utilisée (son micro-avantage réside dans son ancrage communautaire et dans sa légèreté supérieure à celle de son analogue lorsque vectorisée).

✎ Si vous trouvez dans le code source un commentaire qui ne correspond pas à une autre langue, veuillez en informer l’auteur du site, qui étudiera votre suggestion et l’intégrera dans le code source.

Comment convertir les couleurs RGB en L*a*b* ?

Rendez-vous sur la page AWK, C, Dart, Java, JavaScript, Kotlin, Lua, PHP, Python, Ruby ou Rust où un tel convertisseur (utilisant l’illuminant D65) est déjà implémenté en plus de la fonction de comparaison de couleurs.

Plages de valeurs dans CIELAB et interprétation du ΔE2000

Dans l’espace colorimétrique CIELAB, la composante L* représente la luminosité et varie de 0 (noir) à 100 (blanc). Les composantes a* et b* décrivent les axes de couleur : a* s’étend du vert au rouge, tandis que b* va du bleu au jaune. Dans la pratique, les valeurs de a* et b* se situent dans la plage -128 à +127, même si elles peuvent légèrement dépasser ces limites selon les conversions colorimétriques.

Le ΔE2000 (CIEDE2000) quantifie la différence perceptuelle entre deux couleurs : 0 signifie deux couleurs identiques, et des valeurs plus élevées (jusqu’à environ 185 dans les cas extrêmes) indiquent une différence plus marquée. Par exemple, une valeur ΔE2000 autour de 5 correspond à des couleurs proches, tandis qu’une valeur autour de 15 correspond à des couleurs clairement distinctes.

Exemple d’utilisation en TCL

# Compute the Delta E (CIEDE2000) color difference between two L*a*b* colors in TCL

set color_1 { 77.6 32.2 2.3 }
set color_2 { 79.6 37.6 -2.2 }

lassign $color_1 l1 a1 b1
lassign $color_2 l2 a2 b2

set deltaE [ciede_2000  $l1 $a1 $b1 $l2 $a2 $b2]

puts "Delta E 2000 = $deltaE"

# .................................................. This shows a ΔE2000 of 3.6681680203
# As explained in the comments, compliance with Gaurav Sharma would display 3.6681547431

Résultats des tests

Le driver écrit en langage C99, doté de 250 tests statiques précis, a prouvé que cette fonction TCL est interopérable avec la fonction CIEDE2000 mise à disposition dans les autres langages de programmation.

CIEDE2000 Verification Summary :
  First Verified Line : 13,-16,-37,56,-39,6,45.232649568328206
             Duration : 128.97 s
            Successes : 10000000
               Errors : 0
      Average Delta E : 63.2442
    Average Deviation : 4.6e-15
    Maximum Deviation : 1.1e-13

Fichiers à télécharger

Utilisez librement ces fichiers mis à disposition par Michel, même à des fins commerciales.

Communauté

Si vous souhaitez laisser votre avis sur ce code source TCL ou sur CIEDE2000 en général, le livre d’or contient déjà 1 messages en français, et 9 messages au total, alors laissez-nous savoir ce que vous pensez.