Implémentation de CIEDE2000 en Pascal

Cette page présente une implémentation de référence de la formule de différence de couleur CIEDE2000 en Pascal. Si vous souhaitez assurer une compatibilité parfaite (à la dixième décimale) avec certaines implémentations tierces, vous devrez peut-être modifier les commentaires dans le code source. Pour vous faciliter la tâche, le lien suivant automatise cette opération.

La fonction ΔE2000 en Pascal

Considérons la plus courante et académique (Sharma, 2005) des deux formulations.

// Cette fonction écrite en Pascal est placée dans le domaine public et
// n’est pas affiliée à la CIE (Commission Internationale de l’Éclairage).

uses
	Math;

// L’implémentation CIEDE2000 classique qui accepte deux couleurs L*a*b* et renvoie leur différence.
// La composante "L" varie de 0 à 100. "a" et "b", non bornées, sont souvent projetées entre -128 et 127.
function ciede_2000(l_1, a_1, b_1, l_2, a_2, b_2: Double): Double;
var
	k_l, k_c, k_h, n, c_1, c_2, h_1, h_2, h_m, h_d, p, r_t, l, t, h, c: Double;
begin
	// Traite la formule de différence de couleurs CIEDE2000 en Pascal.
	// k_l, k_c et k_h sont des facteurs paramétriques qu’on ajuste
	// selon des recommandations propres au secteur industriel.
	k_l := 1.0;
	k_c := 1.0;
	k_h := 1.0;
	n := (sqrt(a_1 * a_1 + b_1 * b_1) + sqrt(a_2 * a_2 + b_2 * b_2)) * 0.5;
	n := n * n * n * n * n * n * n;
	// Un facteur impliquant la chroma moyenne à la puissance 7,
	// conçu pour modéliser plus précisément son influence.
	n := 1.0 + 0.5 * (1.0 - sqrt(n / (n + 6103515625.0)));
	// Application du facteur de correction de la chroma pour compenser sa non-linéarité.
	c_1 := sqrt(a_1 * a_1 * n * n + b_1 * b_1);
	c_2 := sqrt(a_2 * a_2 * n * n + b_2 * b_2);
	// La fonction atan2 est préférée à atan car elle calcule l’angle d’un
	// point (x, y) dans tous les quadrants, en tenant compte du signe de x et y.
	h_1 := arctan2(b_1, a_1 * n);
	h_2 := arctan2(b_2, a_2 * n);
	if h_1 < 0.0 then h_1 := h_1 + 2.0 * Pi;
	if h_2 < 0.0 then h_2 := h_2 + 2.0 * Pi;
	n := abs(h_2 - h_1);
	// Prévient le branchement de dépendre du RoundingMode du langage de programmation.
	if abs(Pi - n) < 1E-14 then n := Pi;
	// Lorsque les angles de teinte sont dans différents quadrants,
	// la moyenne arithmétique simple peut donner un angle incorrect,
	// les lignes suivantes prennent en compte cette correction angulaire.
	h_m := (h_1 + h_2) * 0.5;
	h_d := (h_2 - h_1) * 0.5;
	if Pi < n then
	begin
		h_d := h_d + Pi;
		// 📜 La formulation de Sharma n’utilise pas la ligne suivante, mais plutôt celle d’après.
		// Note : ces deux variantes ne diffèrent que de ±0,0003 sur la différence de couleur finale.
		h_m := h_m + Pi;
  		// if h_m < Pi then h_m := h_m + Pi else h_m := h_m - Pi;
	end;
	p := 36.0 * h_m - 55.0 * Pi;
	n := (c_1 + c_2) * 0.5;
	n := n * n * n * n * n * n * n;
	// Le terme de correction de la rotation de teinte ajuste le comportement
	// de l’algorithme, d’autant plus si la comparaison porte sur des teintes bleues.
	r_t := -2.0 * sqrt(n / (n + 6103515625.0))
			* sin(Pi / 3.0 * exp(p * p / (-25.0 * Pi * Pi)));
	n := (l_1 + l_2) * 0.5;
	n := (n - 50.0) * (n - 50.0);
	// Luminosité.
	l := (l_2 - l_1) / (k_l * (1.0 + 0.015 * n / sqrt(20.0 + n)));
	// Ces coefficients modulent l’influence des composantes
	// harmoniques dans le calcul de la différence de teinte.
	t := 1.0 	+ 0.24 * sin(2.0 * h_m + Pi / 2.0)
			+ 0.32 * sin(3.0 * h_m + 8.0 * Pi / 15.0)
			- 0.17 * sin(h_m + Pi / 3.0)
			- 0.20 * sin(4.0 * h_m + 3.0 * Pi / 20.0);
	n := c_1 + c_2;
	// Teinte.
	h := 2.0 * sqrt(c_1 * c_2) * sin(h_d) / (k_h * (1.0 + 0.0075 * n * t));
	// Chroma.
	c := (c_2 - c_1) / (k_c * (1.0 + 0.0225 * n));
	// Retourner la racine carrée assure que dE00 représente une distance
	// géométrique (comprise entre 0 et environ 185) dans l’espace CIELAB.
	Exit(sqrt(l * l + h * h + c * c + c * h * r_t));
end;

//    Projet GitHub : https://github.com/michel-leonard/ciede2000-color-matching
//   Tests en ligne : https://michel-leonard.github.io/ciede2000-color-matching

// L1 = 40.9   a1 = 22.7   b1 = 4.1
// L2 = 41.1   a2 = 28.1   b2 = -3.6
// CIE ΔE00 = 5.6213040434 (Bruce Lindbloom, Netflix’s VMAF, ...)
// CIE ΔE00 = 5.6212902503 (Gaurav Sharma, OpenJDK, ...)
// Écart entre les implémentations ≈ 1.4e-5

// Voir les commentaires du code source pour passer d’une de ces variantes d’implémentation de ΔE*00 à l’autre.

Paramètres k_l, k_c et k_h

Les paramètres k_l, k_c et k_h de la formule CIEDE2000 sont des facteurs de pondération appliqués respectivement aux composantes de luminosité (ΔL*), de chroma (ΔC*) et de teinte (ΔH*). Dans le code source, ils sont définis comme des constantes dont la valeur par défaut est 1, ce qui correspond aux conditions d’observation standard prévues par la Commission internationale de l’éclairage (CIE). En pratique, il peut être nécessaire d’ajuster ces coefficients en fonction de conditions spécifiques : par exemple, k_l = 2 est parfois utilisé pour donner plus de poids aux différences de luminosité (cas fréquent dans l’industrie textile), tandis que k_c ou k_h peuvent être réduits pour augmenter la tolérance aux variations de saturation ou de teinte, en fonction des besoins. Selon le contexte, ces coefficients sont généralement compris entre 0,5 et 2.

Précision et fiabilité du code source

La différence entre la formulation académique de Sharma et la formulation simplifiée de Lindbloom ne dépasse pas ±0,0003 sur le ΔE2000 final. Cela correspond à la différence habituellement mesurée entre deux implémentations 32 bits et est imperceptible à l’œil humain. Nos implémentations 64 bits, toutes cohérentes entre elles, garantissent au moins 10 décimales correctes, de sorte que le choix d’une formulation par rapport à l’autre est un détail technique. La formule par défaut sur cette page est celle qui est le plus souvent présentée dans la communauté, elle est légèrement plus facile à vectoriser.

✎ Si vous constatez que les commentaires dans le code source ne correspondent pas aux commentaires en anglais, veuillez en informer l’auteur de la page afin que cela soit corrigé.

Comment convertir les couleurs RGB en L*a*b* ?

Rendez-vous sur la page AWK, C, Dart, Java, JavaScript, Kotlin, Lua, PHP, Python, Ruby ou Rust où un tel convertisseur (utilisant l’illuminant D65) est déjà implémenté en plus de la fonction de comparaison de couleurs.

Plages de valeurs dans CIELAB et interprétation du ΔE2000

Dans l’espace colorimétrique CIELAB, la composante L* représente la luminosité et varie de 0 (noir) à 100 (blanc). Les composantes a* et b* décrivent les axes de couleur : a* s’étend du vert au rouge, tandis que b* va du bleu au jaune. Dans la pratique, les valeurs de a* et b* se situent dans la plage -128 à +127, même si elles peuvent légèrement dépasser ces limites selon les conversions colorimétriques.

Le ΔE2000 (CIEDE2000) quantifie la différence perceptuelle entre deux couleurs : 0 signifie deux couleurs identiques, et des valeurs plus élevées (jusqu’à environ 185 dans les cas extrêmes) indiquent une différence plus marquée. Par exemple, une valeur ΔE2000 autour de 5 correspond à des couleurs proches, tandis qu’une valeur autour de 15 correspond à des couleurs clairement distinctes.

Exemple d’utilisation en Pascal

// Calculate ΔE*00 between two colors in L*a*b* space
var
  l1, a1, b1, l2, a2, b2, deltaE: Double;
begin
  l1 := 31.8; a1 := 22.9; b1 := 4.8;
  l2 := 30.2; a2 := 18.7; b2 := -3.7;

  deltaE := ciede_2000(l1, a1, b1, l2, a2, b2);
  writeln('CIEDE2000 = ', deltaE:0:10);
end.

// .................................................. This shows a ΔE2000 of 6.1884550095
// As explained in the comments, compliance with Gaurav Sharma would display 6.1884708040

Résultats des tests

Le driver écrit en langage C99, doté de 250 tests statiques précis, a prouvé que cette fonction Pascal est interopérable avec la fonction CIEDE2000 mise à disposition dans les autres langages de programmation.

CIEDE2000 Verification Summary :
  First Verified Line : 89.9,44,33,7,-75.04,-57,120.27117304507197559
             Duration : 33.38 s
            Successes : 10000000
               Errors : 0
      Average Delta E : 62.9452
    Average Deviation : 1.4059798381094168e-14
    Maximum Deviation : 3.4106051316484809e-13

Fichiers à télécharger

Utilisez librement ces fichiers mis à disposition par Michel, même à des fins commerciales.

Communauté

Que pensez-vous de ce code source ou de CIEDE2000 ? Votre avis nous intéresse ! Ce site web spécialisé comporte un livre d’or qui inclut déjà 9 messages dont 1 en français. Faites-y un tour et partagez votre avis.