Implémentation de CIEDE2000 en Haskell

Cette page présente une implémentation de référence de la formule de différence de couleur CIEDE2000 en Haskell. Si vous souhaitez obtenir une correspondance exacte avec des implémentations tierces jusqu’à 10 décimales, vous pourriez avoir à apporter des modifications au code source, notamment en commentant et décommentant quelques lignes, ce qui peut être appliqué automatiquement via le lien suivant.

La fonction ΔE2000 en Haskell

Considérons la plus courante et académique (Sharma, 2005) des deux formulations.

-- Cette fonction écrite en Haskell est placée dans le domaine public et
-- n’est pas affiliée à la CIE (Commission Internationale de l’Éclairage).

-- L’implémentation CIEDE2000 classique qui accepte deux couleurs L*a*b* et renvoie leur différence.
-- La composante "L" varie de 0 à 100. "a" et "b", non bornées, sont souvent projetées entre -128 et 127.
ciede_2000 :: Double -> Double -> Double -> Double -> Double -> Double -> Double
ciede_2000 l_1 a_1 b_1 l_2 a_2 b_2 =
  -- Traite la formule de différence de couleurs CIEDE2000 en Haskell.
  -- k_l, k_c et k_h sont des facteurs paramétriques qu’on ajuste
  -- selon des recommandations propres au secteur industriel.
  let
    k_l = 1.0
    k_c = 1.0
    k_h = 1.0
    n = (\() ->
      let
        x = (sqrt(a_1 * a_1 + b_1 * b_1) + sqrt(a_2 * a_2 + b_2 * b_2)) * 0.5
      -- Un facteur impliquant la chroma moyenne à la puissance 7,
      -- conçu pour modéliser plus précisément son influence.
        y = x * x * x * x * x * x * x
      in 1.0 + 0.5 * (1.0 - sqrt(y / (y + 6103515625.0)))
      )()
    -- Application du facteur de correction de la chroma pour compenser sa non-linéarité.
    c_1 = sqrt(a_1 * a_1 * n * n + b_1 * b_1)
    c_2 = sqrt(a_2 * a_2 * n * n + b_2 * b_2)
    -- La fonction atan2 est préférée à atan car elle calcule l’angle d’un
    -- point (x, y) dans tous les quadrants, en tenant compte du signe de x et y.
    h_1 = (\() -> let x = atan2 b_1 (a_1 * n) in if x < 0.0 then x + 2.0 * pi else x)()
    h_2 = (\() -> let x = atan2 b_2 (a_2 * n) in if x < 0.0 then x + 2.0 * pi else x)()
    -- Prévient le branchement de dépendre du RoundingMode du langage de programmation.
    n_0 = (\() -> let x = abs(h_2 - h_1) in if pi - 1E-14 < x && x < pi + 1E-14 then pi else x)()
    -- Lorsque les angles de teinte sont dans différents quadrants,
    -- la moyenne arithmétique simple peut donner un angle incorrect,
    -- les lignes suivantes prennent en compte cette correction angulaire.
    h_m = (\() ->
      let
        x = (h_1 + h_2) * 0.5
        -- 📜 La formulation de Sharma n’utilise pas la ligne suivante, mais plutôt celle d’après.
        -- Note : ces deux variantes ne diffèrent que de ±0,0003 sur la différence de couleur finale.
        in if pi < n_0 then x + pi else x
        -- in if pi < n_0 then if x < pi then x + pi else x - pi else x
      )()
    h_d = (\() ->
      let
        x = (h_2 - h_1) * 0.5
        in if pi < n_0 then x + pi else x
      )()
    p = 36.0 * h_m - 55.0 * pi
    n_2 = (\() -> let x = (c_1 + c_2) * 0.5 in x * x * x * x * x * x * x)()
    -- Le terme de correction de la rotation de teinte ajuste le comportement
    -- de l’algorithme, d’autant plus si la comparaison porte sur des teintes bleues.
    r_t = -2.0 * sqrt(n_2 / (n_2 + 6103515625.0))
                    * sin(pi / 3.0 * exp(p * p / (-25.0 * pi * pi)))
    n_3 = (\() -> let x = (l_1 + l_2) * 0.5 in (x - 50.0) * (x - 50.0))()
    -- Luminosité.
    l = (l_2 - l_1) / (k_l * (1.0 + 0.015 * n_3 / sqrt(20.0 + n_3)))
    -- Ces coefficients modulent l’influence des composantes
    -- harmoniques dans le calcul de la différence de teinte.
    t = 1.0 + 0.24 * sin(2.0 * h_m + pi * 0.5)
            + 0.32 * sin(3.0 * h_m + 8.0 * pi / 15.0)
            - 0.17 * sin(h_m + pi / 3.0)
            - 0.20 * sin(4.0 * h_m + 3.0 * pi / 20.0)
    n_4 = c_1 + c_2
    -- Teinte.
    h = 2.0 * sqrt(c_1 * c_2) * sin(h_d) / (k_h * (1.0 + 0.0075 * n_4 * t))
    -- Chroma.
    c = (c_2 - c_1) / (k_c * (1.0 + 0.0225 * n_4))
    -- Retourner la racine carrée assure que dE00 représente une distance
    -- géométrique (comprise entre 0 et environ 185) dans l’espace CIELAB.
    in sqrt(l * l + h * h + c * c + c * h * r_t)

--    Projet GitHub : https://github.com/michel-leonard/ciede2000-color-matching
--   Tests en ligne : https://michel-leonard.github.io/ciede2000-color-matching

-- L1 = 7.2    a1 = 38.5   b1 = -3.1
-- L2 = 9.7    a2 = 33.4   b2 = 3.4
-- CIE ΔE00 = 4.5328074831 (Bruce Lindbloom, Netflix’s VMAF, ...)
-- CIE ΔE00 = 4.5327941344 (Gaurav Sharma, OpenJDK, ...)
-- Écart entre les implémentations ≈ 1.3e-5

-- Voir les commentaires du code source pour passer d’une de ces variantes d’implémentation de ΔE*00 à l’autre.

Précision et fiabilité du code source

La différence entre les formulations de Sharma et Lindbloom ne dépasse jamais ±0,0003 sur le ΔE2000 final, ce qui correspond à l’écart habituel mesuré entre deux implémentations 32 bits et est imperceptible à l’œil humain. Nos implémentations 64 bits, toutes cohérentes entre elles, garantissent au moins 10 décimales correctes, de sorte que le choix d’une formulation plutôt qu’une autre dépend surtout de l’interopérabilité souhaitée. La formulation qui apparait par défaut sur cette page est la plus couramment utilisée (son micro-avantage réside dans son ancrage communautaire et dans sa légèreté supérieure à celle de son analogue lorsque vectorisée).

✎ Si vous trouvez dans le code source un commentaire qui ne correspond pas à une autre langue, veuillez en informer l’auteur du site, qui étudiera votre suggestion et l’intégrera dans le code source.

Comment convertir les couleurs RGB en L*a*b* ?

Rendez-vous sur la page AWK, C, Dart, Java, JavaScript, Kotlin, Lua, PHP, Python, Ruby ou Rust où un tel convertisseur (utilisant l’illuminant D65) est déjà implémenté en plus de la fonction de comparaison de couleurs.

Plages de valeurs dans CIELAB et interprétation du ΔE2000

Dans l’espace colorimétrique CIELAB, la composante L* représente la luminosité et varie de 0 (noir) à 100 (blanc). Les composantes a* et b* décrivent les axes de couleur : a* s’étend du vert au rouge, tandis que b* va du bleu au jaune. Dans la pratique, les valeurs de a* et b* se situent dans la plage -128 à +127, même si elles peuvent légèrement dépasser ces limites selon les conversions colorimétriques.

Le ΔE2000 (CIEDE2000) quantifie la différence perceptuelle entre deux couleurs : 0 signifie deux couleurs identiques, et des valeurs plus élevées (jusqu’à environ 185 dans les cas extrêmes) indiquent une différence plus marquée. Par exemple, une valeur ΔE2000 autour de 5 correspond à des couleurs proches, tandis qu’une valeur autour de 15 correspond à des couleurs clairement distinctes.

Exemple d’utilisation en Haskell

-- Compute the Delta E (CIEDE2000) color difference between two L*a*b* colors in Haskell

let (l1, a1, b1) = (46.9, 56.7, -2.5)
let (l2, a2, b2) = (46.6, 50.7, 2.3)

let deltaE = ciede_2000 l1 a1 b1 l2 a2 b2
print deltaE

-- .................................................. This shows a ΔE2000 of 2.9263291321
-- As explained in the comments, compliance with Gaurav Sharma would display 2.9263153756

Résultats des tests

Le driver écrit en langage C99, doté de 250 tests statiques précis, a prouvé que cette fonction Haskell est interopérable avec la fonction CIEDE2000 mise à disposition dans les autres langages de programmation.

CIEDE2000 Verification Summary :
  First Verified Line : 12.4,99.83,118.99,89,-20.83,-36,98.92538006135425000
             Duration : 193.11 s
            Successes : 10000000
               Errors : 0
      Average Delta E : 62.9407
    Average Deviation : 6.5393301024174734e-15
    Maximum Deviation : 2.7000623958883807e-13

Fichiers à télécharger

Utilisez librement ces fichiers mis à disposition par Michel, même à des fins commerciales.

Communauté

Si vous souhaitez laisser votre avis sur ce code source Haskell ou sur CIEDE2000 en général, le livre d’or contient déjà 1 messages en français, et 9 messages au total, alors laissez-nous savoir ce que vous pensez.