Реализация CIEDE2000 на Haskell

На этой странице представлена эталонная реализация формулы отличия цветов CIEDE2000 на Haskell. Если вы хотите обеспечить идеальную совместимость (с точностью до десятого знака после запятой) с некоторыми сторонними реализациями, вам может понадобиться изменить комментарии в исходном коде. Чтобы облегчить эту задачу, следующая ссылка автоматизирует эту операцию.

Функция ΔE2000 в Haskell

Рассмотрим более распространенную и академическую (Sharma, 2005) из двух формулировок.

-- This function written in Haskell is not affiliated with the CIE (International Commission on Illumination),
-- and is released into the public domain. It is provided "as is" without any warranty, express or implied.

-- The classic CIE ΔE2000 implementation, which operates on two L*a*b* colors, and returns their difference.
-- "l" ranges from 0 to 100, while "a" and "b" are unbounded and commonly clamped to the range of -128 to 127.
ciede_2000 :: Double -> Double -> Double -> Double -> Double -> Double -> Double
ciede_2000 l_1 a_1 b_1 l_2 a_2 b_2 =
  -- Working in Haskell with the CIEDE2000 color-difference formula.
  -- k_l, k_c, k_h are parametric factors to be adjusted according to
  -- different viewing parameters such as textures, backgrounds...
  let
    k_l = 1.0
    k_c = 1.0
    k_h = 1.0
    n = (\() ->
      let
        x = (sqrt(a_1 * a_1 + b_1 * b_1) + sqrt(a_2 * a_2 + b_2 * b_2)) * 0.5
      -- A factor involving chroma raised to the power of 7 designed to make
      -- the influence of chroma on the total color difference more accurate.
        y = x * x * x * x * x * x * x
      in 1.0 + 0.5 * (1.0 - sqrt(y / (y + 6103515625.0)))
      )()
    -- Application of the chroma correction factor.
    c_1 = sqrt(a_1 * a_1 * n * n + b_1 * b_1)
    c_2 = sqrt(a_2 * a_2 * n * n + b_2 * b_2)
    -- atan2 is preferred over atan because it accurately computes the angle of
    -- a point (x, y) in all quadrants, handling the signs of both coordinates.
    h_1 = (\() -> let x = atan2 b_1 (a_1 * n) in if x < 0.0 then x + 2.0 * pi else x)()
    h_2 = (\() -> let x = atan2 b_2 (a_2 * n) in if x < 0.0 then x + 2.0 * pi else x)()
    -- Cross-implementation consistent rounding.
    n_0 = (\() -> let x = abs(h_2 - h_1) in if pi - 1E-14 < x && x < pi + 1E-14 then pi else x)()
    -- When the hue angles lie in different quadrants, the straightforward
    -- average can produce a mean that incorrectly suggests a hue angle in
    -- the wrong quadrant, the next lines handle this issue.
    h_m = (\() ->
      let
        x = (h_1 + h_2) * 0.5
        -- 📜 Sharma’s formulation doesn’t use the next line, but the one after it,
        -- and these two variants differ by ±0.0003 on the final color differences.
        in if pi < n_0 then x + pi else x
        -- in if pi < n_0 then if x < pi then x + pi else x - pi else x
      )()
    h_d = (\() ->
      let
        x = (h_2 - h_1) * 0.5
        in if pi < n_0 then x + pi else x
      )()
    p = 36.0 * h_m - 55.0 * pi
    n_2 = (\() -> let x = (c_1 + c_2) * 0.5 in x * x * x * x * x * x * x)()
    -- The hue rotation correction term is designed to account for the
    -- non-linear behavior of hue differences in the blue region.
    r_t = -2.0 * sqrt(n_2 / (n_2 + 6103515625.0))
                    * sin(pi / 3.0 * exp(p * p / (-25.0 * pi * pi)))
    n_3 = (\() -> let x = (l_1 + l_2) * 0.5 in (x - 50.0) * (x - 50.0))()
    -- Lightness.
    l = (l_2 - l_1) / (k_l * (1.0 + 0.015 * n_3 / sqrt(20.0 + n_3)))
    -- These coefficients adjust the impact of different harmonic
    -- components on the hue difference calculation.
    t = 1.0 + 0.24 * sin(2.0 * h_m + pi * 0.5)
            + 0.32 * sin(3.0 * h_m + 8.0 * pi / 15.0)
            - 0.17 * sin(h_m + pi / 3.0)
            - 0.20 * sin(4.0 * h_m + 3.0 * pi / 20.0)
    n_4 = c_1 + c_2
    -- Hue.
    h = 2.0 * sqrt(c_1 * c_2) * sin(h_d) / (k_h * (1.0 + 0.0075 * n_4 * t))
    -- Chroma.
    c = (c_2 - c_1) / (k_c * (1.0 + 0.0225 * n_4))
    -- Returning the square root ensures that dE00 accurately reflects the
    -- geometric distance in color space, which can range from 0 to around 185.
    in sqrt(l * l + h * h + c * c + c * h * r_t)

-- GitHub Project : https://github.com/michel-leonard/ciede2000-color-matching
--   Online Tests : https://michel-leonard.github.io/ciede2000-color-matching

-- L1 = 7.2    a1 = 38.5   b1 = -3.1
-- L2 = 9.7    a2 = 33.4   b2 = 3.4
-- CIE ΔE00 = 4.5328074831 (Bruce Lindbloom, Netflix’s VMAF, ...)
-- CIE ΔE00 = 4.5327941344 (Gaurav Sharma, OpenJDK, ...)
-- Deviation between implementations ≈ 1.3e-5

-- See the source code comments for easy switching between these two widely used ΔE*00 implementation variants.

Параметры k_l, k_c и k_h

Параметры k_l, k_c и k_h в формуле CIEDE2000 представляют собой весовые коэффициенты, применяемые соответственно к компонентам яркости (ΔL*), хромы (ΔC*) и тон (ΔH*). В исходном коде они определены как константы со значением по умолчанию 1, что соответствует стандартным условиям наблюдения, установленным Международной комиссией по освещению (CIE). На практике может потребоваться корректировка этих коэффициентов с учетом конкретных условий: например, k_l = 2 иногда используется для придания большего веса различиям в яркости (обычное явление в текстильной промышленности), а k_c или k_h могут быть уменьшены для повышения толерантности к вариациям насыщенности или оттенка, в зависимости от требований. Эти коэффициенты обычно варьируются от 0,5 до 2.

Точность и надежность исходного кода

Разница между академической формулировкой Шармы и упрощенной формулировкой Линдблума не превышает ±0,0003 по конечному значению ΔE2000. Это соответствует разнице, обычно измеряемой между двумя 32-битными реализациями, и незаметно для человеческого глаза. Наши 64-битные реализации, согласующиеся друг с другом, гарантируют не менее 10 правильных десятичных знаков, поэтому выбор одной формулы вместо другой является технической деталью. Формула по умолчанию на этой странице - та, которая чаще всего встречается в сообществе, ее немного проще векторизовать.

✎ Если вы заметили, что комментарии в исходном коде не совпадают с комментариями на английском языке, пожалуйста, сообщите об этом автору страницы, чтобы это можно было исправить.

Как преобразовать цвета RGB в L*a*b*?

Перейдите на страницу AWK, C, Dart, Java, JavaScript, Kotlin, Lua, PHP, Python, Ruby или Rust, где такой конвертер (с использованием осветителя D65) уже реализован в дополнение к функции сравнения цветов.

Диапазоны значений в CIELAB и интерпретация ΔE2000

В цветовом пространстве CIELAB компонент L* обозначает светлоту и обычно изменяется от 0 (черный) до 100 (белый). Компоненты a* и b* описывают цветовые оси: a* идет от зеленого к красному, а b* — от синего к желтому. На практике значения a* и b* чаще всего находятся в диапазоне от -128 до +127, хотя в зависимости от конверсии они могут немного выходить за эти пределы.

ΔE2000 (CIEDE2000) измеряет воспринимаемую разницу между двумя цветами: 0 означает идентичные цвета, а более высокие значения (до примерно 185 в крайних случаях) показывают большую разницу. Например, значение ΔE2000 около 5 означает близкие цвета, а около 15 — явно разные.

Пример использования в Haskell

-- Compute the Delta E (CIEDE2000) color difference between two L*a*b* colors in Haskell

let (l1, a1, b1) = (46.9, 56.7, -2.5)
let (l2, a2, b2) = (46.6, 50.7, 2.3)

let deltaE = ciede_2000 l1 a1 b1 l2 a2 b2
print deltaE

-- .................................................. This shows a ΔE2000 of 2.9263291321
-- As explained in the comments, compliance with Gaurav Sharma would display 2.9263153756

Результаты испытаний

Драйвер, написанный на языке C99, с помощью 250 точных статических тестов доказал, что эта функция Haskell совместима с функцией CIEDE2000, доступной на других языках программирования.

CIEDE2000 Verification Summary :
  First Verified Line : 12.4,99.83,118.99,89,-20.83,-36,98.92538006135425000
             Duration : 193.11 s
            Successes : 10000000
               Errors : 0
      Average Delta E : 62.9407
    Average Deviation : 6.5393301024174734e-15
    Maximum Deviation : 2.7000623958883807e-13

Файлы для загрузки

Не стесняйтесь использовать эти файлы, предоставленные Мишелем, даже в коммерческих целях.

Сообщество

Что вы думаете об этом исходном коде или CIEDE2000? Ваше мнение очень важно для нас! В гостевой книге уже 9 сообщений, в том числе 1 на русском языке. Посмотрите и поделитесь своим мнением.