Реализация CIEDE2000 на AWK

На этой странице представлена эталонная реализация формулы отличия цветов CIEDE2000, написанная на языке программирования AWK. Если вы хотите обеспечить идеальную совместимость (с точностью до десятого знака после запятой) с некоторыми сторонними реализациями, вам может понадобиться изменить комментарии в исходном коде. Чтобы упростить вам эту задачу, следующая ссылка автоматизирует эту операцию.

Функция ΔE2000 в AWK

Рассмотрим более распространенную и академическую (Sharma, 2005) из двух формулировок.

# This function written in AWK is not affiliated with the CIE (International Commission on Illumination),
# and is released into the public domain. It is provided "as is" without any warranty, express or implied.

BEGIN {
	# k_l, k_c, k_h are parametric factors to be adjusted according to
	# different viewing parameters such as textures, backgrounds...
	k_l = k_c = k_h = 1.0
	FS = ","
	M_PI = 3.14159265358979323846264338328
}

{
	# Receives a 6-column CSV file through a pipe and adds the color difference as the last column.
	sub(/\r$/, "") # Normalize Windows files
	printf("%s,%.15g\n", $0, ciede_2000($1, $2, $3, $4, $5, $6))
}

# The classic CIE ΔE2000 implementation, which operates on two L*a*b* colors, and returns their difference.
# "l" ranges from 0 to 100, while "a" and "b" are unbounded and commonly clamped to the range of -128 to 127.
function ciede_2000(l_1, a_1, b_1, l_2, a_2, b_2) {
	# Working in AWK with the CIEDE2000 color-difference formula.
	n = (sqrt(a_1 * a_1 + b_1 * b_1) + sqrt(a_2 * a_2 + b_2 * b_2)) * 0.5
	n = n * n * n * n * n * n * n
	# A factor involving chroma raised to the power of 7 designed to make
	# the influence of chroma on the total color difference more accurate.
	n = 1.0 + 0.5 * (1.0 - sqrt(n / (n + 6103515625.0)))
	# Application of the chroma correction factor.
	c_1 = sqrt(a_1 * a_1 * n * n + b_1 * b_1)
	c_2 = sqrt(a_2 * a_2 * n * n + b_2 * b_2)
	# atan2 is preferred over atan because it accurately computes the angle of
	# a point (x, y) in all quadrants, handling the signs of both coordinates.
	h_1 = atan2(b_1, a_1 * n)
	h_2 = atan2(b_2, a_2 * n)
	if (h_1 < 0.0) h_1 += 2.0 * M_PI
	h_2 += 2.0 * M_PI * (h_2 < 0.0)
	n = h_2 < h_1 ? h_1 - h_2 : h_2 - h_1
	# Cross-implementation consistent rounding.
	if (M_PI - 1E-14 < n && n < M_PI + 1E-14)
		n = M_PI
	# When the hue angles lie in different quadrants, the straightforward
	# average can produce a mean that incorrectly suggests a hue angle in
	# the wrong quadrant, the next lines handle this issue.
	h_m = (h_1 + h_2) * 0.5
	h_d = (h_2 - h_1) * 0.5
	if (M_PI < n) {
		h_d += M_PI
		# 📜 Sharma’s formulation doesn’t use the next line, but the one after it,
		# and these two variants differ by ±0.0003 on the final color differences.
		h_m += M_PI
		# h_m += ((h_m < M_PI) - (M_PI <= h_m)) * M_PI
	}
	p = 36.0 * h_m - 55.0 * M_PI
	n = (c_1 + c_2) * 0.5
	n = n * n * n * n * n * n * n
	# The hue rotation correction term is designed to account for the
	# non-linear behavior of hue differences in the blue region.
	r_t = -2.0 * sqrt(n / (n + 6103515625.0)) \
			* sin(M_PI / 3.0 * exp(p * p / (-25.0 * M_PI * M_PI)))
	n = (l_1 + l_2) * 0.5
	n = (n - 50.0) * (n - 50.0)
	# Lightness.
	l = (l_2 - l_1) / (k_l * (1.0 + 0.015 * n / sqrt(20.0 + n)))
	# These coefficients adjust the impact of different harmonic
	# components on the hue difference calculation.
	t = 1.0	+ 0.24 * sin(2.0 * h_m + M_PI * 0.5) \
		+ 0.32 * sin(3.0 * h_m + 8.0 * M_PI / 15.0) \
		- 0.17 * sin(h_m + M_PI / 3.0) \
		- 0.20 * sin(4.0 * h_m + 3.0 * M_PI / 20.0)
	n = c_1 + c_2
	# Hue.
	h = 2.0 * sqrt(c_1 * c_2) * sin(h_d) / (k_h * (1.0 + 0.0075 * n * t))
	# Chroma.
	c = (c_2 - c_1) / (k_c * (1.0 + 0.0225 * n))
	# Returning the square root ensures that dE00 accurately reflects the
	# geometric distance in color space, which can range from 0 to around 185.
	return sqrt(l * l + h * h + c * c + c * h * r_t)
}

# GitHub Project : https://github.com/michel-leonard/ciede2000-color-matching
#   Online Tests : https://michel-leonard.github.io/ciede2000-color-matching

# L1 = 57.7   a1 = 17.2   b1 = -2.8
# L2 = 56.2   a2 = 22.9   b2 = 4.2
# CIE ΔE00 = 5.8591939826 (Bruce Lindbloom, Netflix’s VMAF, ...)
# CIE ΔE00 = 5.8592116089 (Gaurav Sharma, OpenJDK, ...)
# Deviation between implementations ≈ 1.8e-5

# See the source code comments for easy switching between these two widely used ΔE*00 implementation variants.

Параметры k_l, k_c и k_h

Параметры k_l, k_c и k_h в формуле CIEDE2000 представляют собой весовые коэффициенты, применяемые соответственно к компонентам яркости (ΔL*), хромы (ΔC*) и тон (ΔH*). В исходном коде они определены как константы со значением по умолчанию 1, что соответствует стандартным условиям наблюдения, установленным Международной комиссией по освещению (CIE). На практике может потребоваться корректировка этих коэффициентов с учетом конкретных условий: например, k_l = 2 иногда используется для придания большего веса различиям в яркости (обычное явление в текстильной промышленности), а k_c или k_h могут быть уменьшены для повышения толерантности к вариациям насыщенности или оттенка. В целом эти коэффициенты обычно колеблются в диапазоне от 0,5 до 2, причем наиболее распространенным значением является 1.

Точность и надежность исходного кода

Разница между академической формулировкой Шармы и упрощенной формулировкой Линдблума не превышает ±0,0003 по конечному значению ΔE2000. Представленная здесь реализация является 64-разрядной и обеспечивает точность более 10 знаков после запятой; следовательно, выбор одной формулировки вместо другой является лишь техническим вопросом. В верхней части страницы можно выбрать одну из двух формул; в данный момент отображается упрощённая формула.

Как определить, является ли имеющаяся у меня реализация CIEDE2000 академической версией или упрощенной версией?

• Вычислите ciede_2000(56.6, 43.6, 41.1, 68.4, 9.4, -8.6)
• Если результат равен 30.0001, это академический тип (на Шармы или OpenJDK)
• Если результат равен 29.9999, это упрощенный тип (на Линдблума или Netflix VMAF)

Как преобразовать цвета RGB в L*a*b*?

Для преобразования необходимо использовать промежуточное цветовое пространство XYZ, и если вам нужна помощь, исходный код приведен в нижней части этой страницы (используется точка белого D65, формализованная в 1964 году).

Диапазоны значений в CIELAB и интерпретация ΔE2000

В цветовом пространстве CIELAB компонент L* обозначает светлоту и обычно изменяется от 0 (черный) до 100 (белый). Компоненты a* и b* описывают цветовые оси: a* идет от зеленого к красному, а b* — от синего к желтому. На практике значения a* и b* почти всегда находятся в диапазоне от -128 до +127, хотя в стандарте официальные ограничения для этих двух компонентов не указаны.

ΔE2000 (CIEDE2000) измеряет воспринимаемую разницу между двумя цветами: 0 означает идентичные цвета, а более высокие значения (до 185 и более) показывают большую разницу. Например, значение ΔE2000 около 5 означает близкие цвета, а около 15 — явно разные. Когда значение ΔE2000 превышает 40, сравниваемые цвета практически не имеют ничего общего, и мы больше не можем извлечь из них точной информации.

Пример использования в AWK

awk -f ciede-2000.awk < samples.csv

Результаты испытаний

Наша тестовая программа, написанная на C99, включает 250 строгих статических тестов. Эти тесты гарантируют, что ваши вычисления будут выполняться без ошибок даже в критических предельных случаях, например, когда функция арктангенс возвращает математически неопределенное значение. Результаты показывают, что эта функция CIEDE2000 в AWK совместима с 41 другим языком программирования, которые мы предлагаем.

CIEDE2000 Verification Summary :
  First Verified Line : 69.47,-24,-36,20,-36.8,-94.1,48.6133314128157
             Duration : 56.73 s
            Successes : 10000000
               Errors : 0
      Average Delta E : 62.9396
    Average Deviation : 4.5856684738332374e-14
    Maximum Deviation : 5.6843418860808015e-13

Файлы для загрузки

Не стесняйтесь использовать эти файлы, предоставленные Мишелем, даже в коммерческих целях.

Сообщество

Что вы думаете об этом исходном коде или CIEDE2000? Ваше мнение очень важно для нас! В гостевой книге уже 9 сообщений, в том числе 1 на русском языке. Посмотрите и поделитесь своим мнением.