Реализация CIEDE2000 на Fortran

На этой странице представлена эталонная реализация формулы отличия цветов CIEDE2000 на Fortran. Если вы хотите обеспечить идеальную совместимость (с точностью до десятого знака после запятой) с некоторыми сторонними реализациями, вам может понадобиться изменить комментарии в исходном коде. Чтобы облегчить эту задачу, следующая ссылка автоматизирует эту операцию.

Функция ΔE2000 в Fortran

Рассмотрим более распространенную и академическую (Sharma, 2005) из двух формулировок.

! This function written in Fortran is not affiliated with the CIE (International Commission on Illumination),
! and is released into the public domain. It is provided "as is" without any warranty, express or implied.

module ciede_2000_module
  use iso_fortran_env, only: real64
  implicit none
  private
  public :: ciede_2000
  real(kind=real64), parameter :: M_PI = 3.14159265358979323846264338328_real64
    ! k_l, k_c, k_h are parametric factors to be adjusted according to
    ! different viewing parameters such as textures, backgrounds...
  real(kind=real64), parameter :: k_l = 1.0_real64, k_c = 1.0_real64, k_h = 1.0_real64
contains
  ! The classic CIE ΔE2000 implementation, which operates on two L*a*b* colors, and returns their difference.
  ! "l" ranges from 0 to 100, while "a" and "b" are unbounded and commonly clamped to the range of -128 to 127.
  function ciede_2000(l_1, a_1, b_1, l_2, a_2, b_2) result(delta_e)
    implicit none
    real(kind=real64), intent(in) :: l_1, a_1, b_1, l_2, a_2, b_2
    real(kind=real64) :: n, c_1, c_2, h_1, h_2, h_m, h_d, p, r_t, l, t, h, c, delta_e
    ! Working in Fortran with the CIEDE2000 color-difference formula.
    n = (sqrt(a_1 * a_1 + b_1 * b_1) + sqrt(a_2 * a_2 + b_2 * b_2)) * 0.5_real64
    n = n * n * n * n * n * n * n
    ! A factor involving chroma raised to the power of 7 designed to make
    ! the influence of chroma on the total color difference more accurate.
    n = 1.0_real64 + 0.5_real64 * (1.0_real64 - sqrt(n / (n + 6103515625.0_real64)))
    ! Application of the chroma correction factor.
    c_1 = sqrt(a_1 * a_1 * n * n + b_1 * b_1)
    c_2 = sqrt(a_2 * a_2 * n * n + b_2 * b_2)
    ! atan2 is preferred over atan because it accurately computes the angle of
    ! a point (x, y) in all quadrants, handling the signs of both coordinates.
    h_1 = atan2(b_1, a_1 * n)
    h_2 = atan2(b_2, a_2 * n)
    if (h_1 < 0.0_real64) h_1 = h_1 + 2.0_real64 * M_PI
    if (h_2 < 0.0_real64) h_2 = h_2 + 2.0_real64 * M_PI
    n = abs(h_2 - h_1)
    ! Cross-implementation consistent rounding.
    if (M_PI - 0.00000000000001_real64 < n .and. n < M_PI + 0.00000000000001_real64) n = M_PI
    ! When the hue angles lie in different quadrants, the straightforward
    ! average can produce a mean that incorrectly suggests a hue angle in
    ! the wrong quadrant, the next lines handle this issue.
    h_m = (h_1 + h_2) * 0.5_real64
    h_d = (h_2 - h_1) * 0.5_real64
    if (M_PI < n) then
      h_d = h_d + M_PI
      ! 📜 Sharma’s formulation doesn’t use the next line, but the one after it,
      ! and these two variants differ by ±0.0003 on the final color differences.
      h_m = h_m + M_PI
      ! h_m = h_m + MERGE(M_PI, -M_PI, h_m < M_PI)
    endif
    p = 36.0_real64 * h_m - 55.0_real64 * M_PI
    n = (c_1 + c_2) * 0.5_real64
    n = n * n * n * n * n * n * n
    ! The hue rotation correction term is designed to account for the
    ! non-linear behavior of hue differences in the blue region.
    r_t = -2.0_real64 * sqrt(n / (n + 6103515625.0_real64)) &
                        * sin(M_PI / 3.0_real64 * exp(p * p / (-25.0_real64 * M_PI * M_PI)))
    n = (l_1 + l_2) * 0.5_real64
    n = (n - 50.0_real64) * (n - 50.0_real64)
    ! Lightness.
    l = (l_2 - l_1) / (k_l * (1.0_real64 + 0.015_real64 * n / sqrt(20.0_real64 + n)))
    ! These coefficients adjust the impact of different harmonic
    ! components on the hue difference calculation.
    t = 1.0_real64   + 0.24_real64 * sin(2.0_real64 * h_m + M_PI / 2.0_real64) &
                     + 0.32_real64 * sin(3.0_real64 * h_m + 8.0_real64 * M_PI / 15.0_real64) &
                     - 0.17_real64 * sin(h_m + M_PI / 3.0_real64) &
                     - 0.20_real64 * sin(4.0_real64 * h_m + 3.0_real64 * M_PI / 20.0_real64)
    n = c_1 + c_2
    ! Hue.
    h = 2.0_real64 * sqrt(c_1 * c_2) * sin(h_d) / (k_h * (1.0_real64 + 0.0075_real64 * n * t))
    ! Chroma.
    c = (c_2 - c_1) / (k_c * (1.0_real64 + 0.0225_real64 * n))
    ! Returning the square root ensures that dE00 accurately reflects the
    ! geometric distance in color space, which can range from 0 to around 185.
    delta_e = sqrt(l * l + h * h + c * c + c * h * r_t)
  end function ciede_2000
end module ciede_2000_module

! GitHub Project : https://github.com/michel-leonard/ciede2000-color-matching
!   Online Tests : https://michel-leonard.github.io/ciede2000-color-matching

! L1 = 68.5   a1 = 18.1   b1 = 3.6
! L2 = 70.2   a2 = 23.8   b2 = -4.0
! CIE ΔE00 = 6.1142357448 (Bruce Lindbloom, Netflix’s VMAF, ...)
! CIE ΔE00 = 6.1142186799 (Gaurav Sharma, OpenJDK, ...)
! Deviation between implementations ≈ 1.7e-5

! See the source code comments for easy switching between these two widely used ΔE*00 implementation variants.

Параметры k_l, k_c и k_h

Параметры k_l, k_c и k_h в формуле CIEDE2000 представляют собой весовые коэффициенты, применяемые соответственно к компонентам яркости (ΔL*), хромы (ΔC*) и тон (ΔH*). В исходном коде они определены как константы со значением по умолчанию 1, что соответствует стандартным условиям наблюдения, установленным Международной комиссией по освещению (CIE). На практике может потребоваться корректировка этих коэффициентов с учетом конкретных условий: например, k_l = 2 иногда используется для придания большего веса различиям в яркости (обычное явление в текстильной промышленности), а k_c или k_h могут быть уменьшены для повышения толерантности к вариациям насыщенности или оттенка. В целом эти коэффициенты обычно колеблются в диапазоне от 0,5 до 2, причем наиболее распространенным значением является 1.

Точность и надежность исходного кода

Разница между академической формулировкой Шармы и упрощенной формулировкой Линдблума не превышает ±0,0003 по конечному значению ΔE2000. Это соответствует разнице, обычно измеряемой между двумя 32-битными реализациями, и незаметно для человеческого глаза. Реализация, представленная на этой странице, является 64-битной и обеспечивает точность не менее 10 знаков после запятой; следовательно, выбор одной формулировки вместо другой является лишь техническим вопросом. Формула по умолчанию на этой странице - та, которая чаще всего встречается в сообществе, ее немного проще векторизовать.

✎ Если вы заметите какие-либо несоответствия после сравнения русского и английского текстов, пожалуйста, сообщите об этом автору сайта, чтобы он мог внести исправления.

Как преобразовать цвета RGB в L*a*b*?

Перейдите на страницу AWK, C, Dart, Java, JavaScript, Kotlin, Lua, PHP, Python, Ruby или Rust, где такой конвертер (с использованием осветителя D65) уже реализован в дополнение к функции сравнения цветов.

Диапазоны значений в CIELAB и интерпретация ΔE2000

В цветовом пространстве CIELAB компонент L* обозначает светлоту и обычно изменяется от 0 (черный) до 100 (белый). Компоненты a* и b* описывают цветовые оси: a* идет от зеленого к красному, а b* — от синего к желтому. На практике значения a* и b* почти всегда находятся в диапазоне от -128 до +127, хотя в стандарте официальные ограничения для этих двух компонентов не указаны.

ΔE2000 (CIEDE2000) измеряет воспринимаемую разницу между двумя цветами: 0 означает идентичные цвета, а более высокие значения (до 185 и более) показывают большую разницу. Например, значение ΔE2000 около 5 означает близкие цвета, а около 15 — явно разные. Когда значение ΔE2000 превышает 40, сравниваемые цвета практически не имеют ничего общего, и мы больше не можем извлечь из них точной информации.

Пример использования в Fortran

! Compute the Delta E (CIEDE2000) color difference between two L*a*b* colors in Fortran

! Color 1: l1 = 89.0   a1 = 33.3   b1 = -1.7
! Color 2: l2 = 89.2   a2 = 38.4   b2 = 2.2

delta_e = ciede_2000(l1, a1, b1, l2, a2, b2)
print '(F0.10)', delta_e

! .................................................. This shows a ΔE2000 of 2.9929564263
! As explained in the comments, compliance with Gaurav Sharma would display 2.9929700654

Результаты испытаний

Наша тестовая программа, написанная на C99, включает 250 строгих статических тестов. Результаты показывают, что эта функция CIEDE2000 в TypeScript совместима с 41 другим языком программирования.

CIEDE2000 Verification Summary :
  First Verified Line : 24,122.6,117,21,-40.999999999847,-46,81.762663548041459
             Duration : 41.38 s
            Successes : 10000000
               Errors : 0
      Average Delta E : 63.2338
    Average Deviation : 4.6e-15
    Maximum Deviation : 1.1e-13

Файлы для загрузки

Не стесняйтесь использовать эти файлы, предоставленные Мишелем, даже в коммерческих целях.

Сообщество

Что вы думаете об этом исходном коде или CIEDE2000? Ваше мнение очень важно для нас! В гостевой книге уже 9 сообщений, в том числе 1 на русском языке. Посмотрите и поделитесь своим мнением.