CIEDE2000-Implementierung in Nim

Diese Seite enthält eine Referenzimplementierung der CIEDE2000 Formel für den Farbabstand in Nim. Wenn Sie eine perfekte Kompatibilität (bis zur zehnten Dezimalstelle) mit einigen Implementierungen von Drittanbietern sicherstellen wollen, müssen Sie möglicherweise die Kommentare im Quellcode ändern. Um dies zu erleichtern, automatisiert der folgende Link diesen Vorgang.

Die Funktion ΔE2000 in Nim

Betrachten wir die gängigere und akademische (Sharma, 2005) der beiden Formulierungen.

# This function written in Nim is not affiliated with the CIE (International Commission on Illumination),
# and is released into the public domain. It is provided "as is" without any warranty, express or implied.

import math

const M_PI = 3.14159265358979323846264338328

# The classic CIE ΔE2000 implementation, which operates on two L*a*b* colors, and returns their difference.
# "l" ranges from 0 to 100, while "a" and "b" are unbounded and commonly clamped to the range of -128 to 127.
proc ciede_2000(l_1: float64, a_1: float64, b_1: float64, l_2: float64, a_2: float64, b_2: float64): float64 =
  # Working in Nim with the CIEDE2000 color-difference formula.
  # k_l, k_c, k_h are parametric factors to be adjusted according to
  # different viewing parameters such as textures, backgrounds...
  let k_l = 1.0;
  let k_c = 1.0;
  let k_h = 1.0;
  var n = (sqrt(a_1 * a_1 + b_1 * b_1) + sqrt(a_2 * a_2 + b_2 * b_2)) * 0.5;
  n = n * n * n * n * n * n * n;
  # A factor involving chroma raised to the power of 7 designed to make
  # the influence of chroma on the total color difference more accurate.
  n = 1.0 + 0.5 * (1.0 - sqrt(n / (n + 6103515625.0)));
  # Application of the chroma correction factor.
  let c_1 = sqrt(a_1 * a_1 * n * n + b_1 * b_1);
  let c_2 = sqrt(a_2 * a_2 * n * n + b_2 * b_2);
  # atan2 is preferred over atan because it accurately computes the angle of
  # a point (x, y) in all quadrants, handling the signs of both coordinates.
  var h_1 = arctan2(b_1, a_1 * n);
  var h_2 = arctan2(b_2, a_2 * n);
  h_1 += 2.0 * M_PI * (h_1 < 0.0).float;
  h_2 += 2.0 * M_PI * (h_2 < 0.0).float;
  n = abs(h_2 - h_1);
  # Cross-implementation consistent rounding.
  if M_PI - 1E-14 < n and n < M_PI + 1E-14 :
    n = M_PI;
  # When the hue angles lie in different quadrants, the straightforward
  # average can produce a mean that incorrectly suggests a hue angle in
  # the wrong quadrant, the next lines handle this issue.
  var h_m = (h_1 + h_2) * 0.5;
  var h_d = (h_2 - h_1) * 0.5;
  if M_PI < n :
    h_d += M_PI;
    # 📜 Sharma’s formulation doesn’t use the next line, but the one after it,
    # and these two variants differ by ±0.0003 on the final color differences.
    h_m += M_PI;
    # h_m += (if h_m < M_PI : M_PI else : -M_PI);
  let p = 36.0 * h_m - 55.0 * M_PI;
  n = (c_1 + c_2) * 0.5;
  n = n * n * n * n * n * n * n;
  # The hue rotation correction term is designed to account for the
  # non-linear behavior of hue differences in the blue region.
  let r_t = -2.0 * sqrt(n / (n + 6103515625.0)) *
        sin(M_PI / 3.0 * exp(p * p / (-25.0 * M_PI * M_PI)));
  n = (l_1 + l_2) * 0.5;
  n = (n - 50.0) * (n - 50.0);
  # Lightness.
  let l = (l_2 - l_1) / (k_l * (1.0 + 0.015 * n / sqrt(20.0 + n)));
  # These coefficients adjust the impact of different harmonic
  # components on the hue difference calculation.
  let t = 1.0   + 0.24 * sin(2.0 * h_m + M_PI * 0.5) +
        0.32 * sin(3.0 * h_m + 8.0 * M_PI / 15.0) -
        0.17 * sin(h_m + M_PI / 3.0) -
        0.20 * sin(4.0 * h_m + 3.0 * M_PI / 20.0);
  n = c_1 + c_2;
  # Hue.
  let h = 2.0 * sqrt(c_1 * c_2) * sin(h_d) / (k_h * (1.0 + 0.0075 * n * t));
  # Chroma.
  let c = (c_2 - c_1) / (k_c * (1.0 + 0.0225 * n));
  # Returning the square root ensures that dE00 accurately reflects the
  # geometric distance in color space, which can range from 0 to around 185.
  return sqrt(l * l + h * h + c * c + c * h * r_t);

# GitHub Project : https://github.com/michel-leonard/ciede2000-color-matching
#   Online Tests : https://michel-leonard.github.io/ciede2000-color-matching

# L1 = 61.0   a1 = 39.1   b1 = -2.9
# L2 = 58.7   a2 = 44.6   b2 = 3.8
# CIE ΔE00 = 4.5818409116 (Bruce Lindbloom, Netflix’s VMAF, ...)
# CIE ΔE00 = 4.5818547397 (Gaurav Sharma, OpenJDK, ...)
# Deviation between implementations ≈ 1.4e-5

# See the source code comments for easy switching between these two widely used ΔE*00 implementation variants.

Parameter k_l, k_c und k_h

Die Parameter k_l, k_c und k_h in der CIEDE2000-Formel sind Gewichtungsfaktoren, die jeweils auf die Komponenten Helligkeit (ΔL*), Chroma (ΔC*) und Farbton (ΔH*) angewendet werden. Im Quellcode sind sie als Konstanten definiert, deren Standardwert 1 ist; dies entspricht den von der Internationalen Beleuchtungskommission (CIE) festgelegten Standardbeobachtungsbedingungen. In der Praxis kann es erforderlich sein, diese Koeffizienten an spezifische Bedingungen anzupassen: So wird k_l = 2 manchmal verwendet, um Helligkeitsunterschiede stärker zu gewichten (was in der Textilindustrie häufig vorkommt), während k_c oder k_h je nach den Anforderungen reduziert werden können, um die Toleranz für Sättigungs- oder Farbtonschwankungen zu erhöhen. Je nach Kontext liegen diese Koeffizienten normalerweise zwischen 0,5 und 2.

Genauigkeit und Zuverlässigkeit des Quellcodes

Der Unterschied zwischen der akademischen Formulierung von Sharma und der vereinfachten Formulierung von Lindbloom beträgt nicht mehr als ±0,0003 auf dem endgültigen ΔE2000. Dies entspricht dem Unterschied, der normalerweise zwischen zwei 32-Bit-Implementierungen gemessen wird und für das menschliche Auge nicht wahrnehmbar ist. Unsere 64-Bit-Implementierungen, die alle miteinander übereinstimmen, garantieren mindestens 10 korrekte Nachkommastellen, so dass die Wahl der einen Formulierung gegenüber der anderen ein technisches Detail ist. Die Standardformel auf dieser Seite ist diejenige, die in der Community am häufigsten verwendet wird, sie ist etwas einfacher zu vektorisieren.

✎ Wenn Sie feststellen, dass die Kommentare im Quellcode nicht mit den Kommentaren in Englisch übereinstimmen, informieren Sie bitte den Autor der Seite, damit dies korrigiert werden kann.

Wie kann man RGB-Farben in L*a*b* umwandeln?

Gehen Sie auf die AWK, C, Dart, Java, JavaScript, Kotlin, Lua, PHP, Python, Ruby oder Rust-Seite, wo ein solcher Konverter (unter Verwendung der Lichtart D65) bereits zusätzlich zur Farbabstandsfunktion implementiert ist.

Wertebereiche in CIELAB und Interpretation des ΔE2000

Im CIELAB-Farbraum steht die Komponente L* für die Helligkeit und reicht normalerweise von 0 (schwarz) bis 100 (weiß). Die Komponenten a* und b* beschreiben die Farbachsen: a* verläuft von Grün nach Rot, b* von Blau nach Gelb. In der Praxis sind die Werte von a* und b* fast immer auf einen Bereich zwischen -128 und +127 beschränkt, obwohl der Standard keine offizielle Grenze für diese beiden Komponenten festlegt.

ΔE2000 (CIEDE2000) gibt den wahrgenommenen Unterschied zwischen zwei Farben an: 0 bedeutet identische Farben, höhere Werte (bis zu 185 und mehr) zeigen eine stärkere Abweichung. Beispielsweise entsprechen Werte um 5 eher ähnlichen Farben, während Werte um 15 deutlich unterschiedliche Farben anzeigen. Wenn der Wert ΔE2000 40 übersteigt, haben die verglichenen Farben praktisch nichts mehr gemeinsam, und wir können daraus keine genauen Informationen mehr ableiten.

Anwendungsbeispiel in Nim

# Compute the Delta E (CIEDE2000) color difference between two L*a*b* colors in Nim

let (l1, a1, b1) = (96.8, 44.9, -2.0)
let (l2, a2, b2) = (96.6, 50.4, 2.7)

let delta_e = ciede_2000(l1, a1, b1, l2, a2, b2)
echo delta_e

# .................................................. This shows a ΔE2000 of 2.9776421152
# As explained in the comments, compliance with Gaurav Sharma would display 2.9776552456

Testergebnisse

Der in der Sprache C99 geschriebene und mit 250 präzisen statischen Tests versehene Treiber hat bewiesen, dass diese Nim-Funktion mit der in anderen Programmiersprachen zur Verfügung gestellten CIEDE2000-Funktion interoperabel ist.

CIEDE2000 Verification Summary :
  First Verified Line : 27,-123,101,44,-30,122,29.989372817453113
             Duration : 44.51 s
            Successes : 10000000
               Errors : 0
      Average Delta E : 63.2072
    Average Deviation : 4.3e-15
    Maximum Deviation : 1.1e-13

Dateien zum Herunterladen

Verwenden Sie diese von Michel zur Verfügung gestellten Dateien frei, auch für kommerzielle Zwecke.

Gemeinschaft

Was halten Sie von diesem Quellcode oder von CIEDE2000? Ihre Meinung ist uns wichtig! Das Gästebuch enthält bereits 9 Einträge - davon 1 auf Deutsch. Schauen Sie sich dort um und teilen Sie Ihre Meinung mit.