CIEDE2000-Implementierung in AWK

Diese Seite präsentiert eine Referenzimplementierung der CIEDE2000-Formel für den Farbabstand in AWK. Wenn Sie eine genaue Übereinstimmung mit Implementierungen von Drittanbietern bis zu 10 Dezimalstellen erreichen möchten, müssen Sie möglicherweise Änderungen am Quellcode vornehmen, insbesondere einige Zeilen auskommentieren und dekomentieren, was über den folgenden Link automatisch erfolgen kann.

Die Funktion ΔE2000 in AWK

Betrachten wir die gängigere und akademische (Sharma, 2005) der beiden Formulierungen.

# This function written in AWK is not affiliated with the CIE (International Commission on Illumination),
# and is released into the public domain. It is provided "as is" without any warranty, express or implied.

BEGIN {
	# k_l, k_c, k_h are parametric factors to be adjusted according to
	# different viewing parameters such as textures, backgrounds...
	k_l = k_c = k_h = 1.0
	FS = ","
	M_PI = 3.14159265358979323846264338328
}

{
	# Receives a 6-column CSV file through a pipe and adds the color difference as the last column.
	sub(/\r$/, "") # Normalize Windows files
	printf("%s,%.15g\n", $0, ciede_2000($1, $2, $3, $4, $5, $6))
}

# The classic CIE ΔE2000 implementation, which operates on two L*a*b* colors, and returns their difference.
# "l" ranges from 0 to 100, while "a" and "b" are unbounded and commonly clamped to the range of -128 to 127.
function ciede_2000(l_1, a_1, b_1, l_2, a_2, b_2) {
	# Working in AWK with the CIEDE2000 color-difference formula.
	n = (sqrt(a_1 * a_1 + b_1 * b_1) + sqrt(a_2 * a_2 + b_2 * b_2)) * 0.5
	n = n * n * n * n * n * n * n
	# A factor involving chroma raised to the power of 7 designed to make
	# the influence of chroma on the total color difference more accurate.
	n = 1.0 + 0.5 * (1.0 - sqrt(n / (n + 6103515625.0)))
	# Application of the chroma correction factor.
	c_1 = sqrt(a_1 * a_1 * n * n + b_1 * b_1)
	c_2 = sqrt(a_2 * a_2 * n * n + b_2 * b_2)
	# atan2 is preferred over atan because it accurately computes the angle of
	# a point (x, y) in all quadrants, handling the signs of both coordinates.
	h_1 = atan2(b_1, a_1 * n)
	h_2 = atan2(b_2, a_2 * n)
	if (h_1 < 0.0) h_1 += 2.0 * M_PI
	h_2 += 2.0 * M_PI * (h_2 < 0.0)
	n = h_2 < h_1 ? h_1 - h_2 : h_2 - h_1
	# Cross-implementation consistent rounding.
	if (M_PI - 1E-14 < n && n < M_PI + 1E-14)
		n = M_PI
	# When the hue angles lie in different quadrants, the straightforward
	# average can produce a mean that incorrectly suggests a hue angle in
	# the wrong quadrant, the next lines handle this issue.
	h_m = (h_1 + h_2) * 0.5
	h_d = (h_2 - h_1) * 0.5
	if (M_PI < n) {
		h_d += M_PI
		# 📜 Sharma’s formulation doesn’t use the next line, but the one after it,
		# and these two variants differ by ±0.0003 on the final color differences.
		h_m += M_PI
		# h_m += ((h_m < M_PI) - (M_PI <= h_m)) * M_PI
	}
	p = 36.0 * h_m - 55.0 * M_PI
	n = (c_1 + c_2) * 0.5
	n = n * n * n * n * n * n * n
	# The hue rotation correction term is designed to account for the
	# non-linear behavior of hue differences in the blue region.
	r_t = -2.0 * sqrt(n / (n + 6103515625.0)) \
			* sin(M_PI / 3.0 * exp(p * p / (-25.0 * M_PI * M_PI)))
	n = (l_1 + l_2) * 0.5
	n = (n - 50.0) * (n - 50.0)
	# Lightness.
	l = (l_2 - l_1) / (k_l * (1.0 + 0.015 * n / sqrt(20.0 + n)))
	# These coefficients adjust the impact of different harmonic
	# components on the hue difference calculation.
	t = 1.0	+ 0.24 * sin(2.0 * h_m + M_PI * 0.5) \
		+ 0.32 * sin(3.0 * h_m + 8.0 * M_PI / 15.0) \
		- 0.17 * sin(h_m + M_PI / 3.0) \
		- 0.20 * sin(4.0 * h_m + 3.0 * M_PI / 20.0)
	n = c_1 + c_2
	# Hue.
	h = 2.0 * sqrt(c_1 * c_2) * sin(h_d) / (k_h * (1.0 + 0.0075 * n * t))
	# Chroma.
	c = (c_2 - c_1) / (k_c * (1.0 + 0.0225 * n))
	# Returning the square root ensures that dE00 accurately reflects the
	# geometric distance in color space, which can range from 0 to around 185.
	return sqrt(l * l + h * h + c * c + c * h * r_t)
}

# GitHub Project : https://github.com/michel-leonard/ciede2000-color-matching
#   Online Tests : https://michel-leonard.github.io/ciede2000-color-matching

# L1 = 57.7   a1 = 17.2   b1 = -2.8
# L2 = 56.2   a2 = 22.9   b2 = 4.2
# CIE ΔE00 = 5.8591939826 (Bruce Lindbloom, Netflix’s VMAF, ...)
# CIE ΔE00 = 5.8592116089 (Gaurav Sharma, OpenJDK, ...)
# Deviation between implementations ≈ 1.8e-5

# See the source code comments for easy switching between these two widely used ΔE*00 implementation variants.

Genauigkeit und Zuverlässigkeit des Quellcodes

Der Unterschied zwischen den Formulierungen von Sharma und Lindbloom überschreitet niemals ±0,0003 beim endgültigen ΔE2000, was dem üblichen Unterschied zwischen zwei 32-Bit-Implementierungen entspricht und für das menschliche Auge nicht wahrnehmbar ist. Unsere 64-Bit-Implementierungen, die alle miteinander konsistent sind, garantieren mindestens 10 korrekte Dezimalstellen, sodass die Wahl einer Formulierung gegenüber einer anderen hauptsächlich von der gewünschten Interoperabilität abhängt. Die Formulierung, die standardmäßig auf dieser Seite erscheint, ist die am häufigsten verwendete (ihr Mikrovorteil liegt in ihrer Verankerung in der Gemeinschaft und darin, dass sie leichter ist als ihr Analogon, wenn sie vektorisiert ist).

✎ Wenn Sie im Quellcode einen Kommentar finden, der nicht einer anderen Sprache entspricht, informieren Sie bitte den Autor der Website, der Ihren Vorschlag prüfen und in den Quellcode einarbeiten wird.

Wie kann man RGB-Farben in L*a*b* umwandeln?

Für die Konvertierung müssen Sie den XYZ-Zwischenfarbraum verwenden. Falls Sie Hilfe benötigen, finden Sie den Quellcode am Ende dieser Seite (unter Verwendung des 1964 formalisierten D65-Weißpunkts).

Wertebereiche in CIELAB und Interpretation des ΔE2000

Im CIELAB-Farbraum steht die Komponente L* für die Helligkeit und reicht normalerweise von 0 (schwarz) bis 100 (weiß). Die Komponenten a* und b* beschreiben die Farbachsen: a* verläuft von Grün nach Rot, b* von Blau nach Gelb. In der Praxis liegen a* und b* meist im Bereich von -128 bis +127, können aber je nach Farbumrechnung leicht darüber hinausgehen.

Parameter k_l, k_c und k_h

Die Parameter k_l, k_c und k_h sind Gewichtungsfaktoren, die jeweils auf die Helligkeits- (ΔL*), Chroma- (ΔC*) und Farbton- (ΔH*) Terme in der CIEDE2000-Formel angewendet werden. Ihr Standardwert ist 1, was den von der Internationale Beleuchtungskommission empfohlenen Standardbeobachtungsbedingungen entspricht. In der Praxis werden diese Koeffizienten angepasst, um spezielle Bedingungen widerzuspiegeln: Zum Beispiel wird k_l = 2 manchmal verwendet, um Helligkeitsunterschieden mehr Gewicht zu geben (häufig im Druckwesen), während k_c oder k_h reduziert werden können, um die Toleranz gegenüber Sättigungs- oder Farbtonabweichungen je nach Qualitätskontrolle zu erhöhen. Je nach Kontext liegen diese Koeffizienten typischerweise zwischen 0,5 und 2.

ΔE2000 (CIEDE2000) gibt den wahrgenommenen Unterschied zwischen zwei Farben an: 0 bedeutet identische Farben, höhere Werte (bis etwa 185 in extremen Fällen) zeigen eine stärkere Abweichung. Beispielsweise entsprechen Werte um 5 eher ähnlichen Farben, während Werte um 15 deutlich unterschiedliche Farben anzeigen.

Anwendungsbeispiel in AWK

awk -f ciede-2000.awk < samples.csv

Testergebnisse

Der in der Sprache C99 geschriebene und mit 250 präzisen statischen Tests versehene Treiber hat bewiesen, dass diese AWK-Funktion mit der in anderen Programmiersprachen zur Verfügung gestellten CIEDE2000-Funktion interoperabel ist.

CIEDE2000 Verification Summary :
  First Verified Line : 69.47,-24,-36,20,-36.8,-94.1,48.6133314128157
             Duration : 56.73 s
            Successes : 10000000
               Errors : 0
      Average Delta E : 62.9396
    Average Deviation : 4.5856684738332374e-14
    Maximum Deviation : 5.6843418860808015e-13

Dateien zum Herunterladen

Verwenden Sie diese von Michel zur Verfügung gestellten Dateien frei, auch für kommerzielle Zwecke.

Gemeinschaft

Was halten Sie von diesem Quellcode oder von CIEDE2000? Ihre Meinung ist uns wichtig! Das Gästebuch enthält bereits 9 Einträge - davon 1 auf Deutsch. Schauen Sie sich dort um und teilen Sie Ihre Meinung mit.