Implementación de CIEDE2000 en Pascal

Esta página presenta una implementación de referencia de la fórmula de diferencia de color CIEDE2000 en Pascal. Si desea garantizar una compatibilidad perfecta (hasta el décimo decimal) con algunas implementaciones de terceros, es posible que tenga que modificar los comentarios del código fuente. Para facilitarlo, el siguiente enlace automatiza esta operación.

La función ΔE2000 en Pascal

Consideremos la más común y académica (Sharma, 2005) de las dos formulaciones.

// Esta función escrita en Pascal es de dominio público y no
// está afiliada a la CIE (Comisión Internacional de Iluminación).

uses
	Math;

// La implementación clásica de CIEDE2000 que recibe dos colores L*a*b* y devuelve su diferencia.
// El componente "L" varía de 0 a 100. "a" y "b" normalmente se proyectan entre -128 y 127.
function ciede_2000(l_1, a_1, b_1, l_2, a_2, b_2: Double): Double;
var
	k_l, k_c, k_h, n, c_1, c_2, h_1, h_2, h_m, h_d, p, r_t, l, t, h, c: Double;
begin
	// Ejecuta el cálculo de diferencia de color CIEDE2000 en Pascal.
	// k_l, k_c y k_h son factores paramétricos a ajustar según
	// sus necesidades de visualización (texturas, fondos).
	k_l := 1.0;
	k_c := 1.0;
	k_h := 1.0;
	n := (sqrt(a_1 * a_1 + b_1 * b_1) + sqrt(a_2 * a_2 + b_2 * b_2)) * 0.5;
	n := n * n * n * n * n * n * n;
	// Un factor que implica la croma elevada a la potencia 7,
	// diseñado para tener más en cuenta la influencia de la croma.
	n := 1.0 + 0.5 * (1.0 - sqrt(n / (n + 6103515625.0)));
	// Aplicación del factor de corrección de la croma para compensar su no linealidad.
	c_1 := sqrt(a_1 * a_1 * n * n + b_1 * b_1);
	c_2 := sqrt(a_2 * a_2 * n * n + b_2 * b_2);
	// La función atan2 es preferible a atan porque calcula el ángulo de un
	// punto (x, y) en todos los cuadrantes, teniendo en cuenta el signo de x e y.
	h_1 := arctan2(b_1, a_1 * n);
	h_2 := arctan2(b_2, a_2 * n);
	if h_1 < 0.0 then h_1 := h_1 + 2.0 * Pi;
	if h_2 < 0.0 then h_2 := h_2 + 2.0 * Pi;
	n := abs(h_2 - h_1);
	// Evita que la rama dependa del RoundingMode del lenguaje de programación.
	if abs(Pi - n) < 1E-14 then n := Pi;
	// Cuando los ángulos de tono se encuentran en diferentes cuadrantes,
	// la media aritmética simple puede dar un ángulo incorrecto, las
	// líneas siguientes aplican la corrección angular necesaria.
	h_m := (h_1 + h_2) * 0.5;
	h_d := (h_2 - h_1) * 0.5;
	if Pi < n then
	begin
		h_d := h_d + Pi;
		// 📜 La formulación de Sharma no utiliza la línea siguiente, sino la que le sigue.
		// Nota: estas dos variantes sólo difieren en ±0,0003 en la diferencia de color final.
		h_m := h_m + Pi;
  		// if h_m < Pi then h_m := h_m + Pi else h_m := h_m - Pi;
	end;
	p := 36.0 * h_m - 55.0 * Pi;
	n := (c_1 + c_2) * 0.5;
	n := n * n * n * n * n * n * n;
	// El término de corrección de la rotación del tono mejora la precisión
	// del algoritmo, especialmente cuando la comparación se refiere a azules.
	r_t := -2.0 * sqrt(n / (n + 6103515625.0))
			* sin(Pi / 3.0 * exp(p * p / (-25.0 * Pi * Pi)));
	n := (l_1 + l_2) * 0.5;
	n := (n - 50.0) * (n - 50.0);
	//  Luminosidad .
	l := (l_2 - l_1) / (k_l * (1.0 + 0.015 * n / sqrt(20.0 + n)));
	// Estos coeficientes se utilizan para modular la influencia de
	// los componentes armónicos en el cálculo de la diferencia de tono.
	t := 1.0 	+ 0.24 * sin(2.0 * h_m + Pi / 2.0)
			+ 0.32 * sin(3.0 * h_m + 8.0 * Pi / 15.0)
			- 0.17 * sin(h_m + Pi / 3.0)
			- 0.20 * sin(4.0 * h_m + 3.0 * Pi / 20.0);
	n := c_1 + c_2;
	// Tono.
	h := 2.0 * sqrt(c_1 * c_2) * sin(h_d) / (k_h * (1.0 + 0.0075 * n * t));
	// Croma.
	c := (c_2 - c_1) / (k_c * (1.0 + 0.0225 * n));
	// Devolver la raíz cuadrada garantiza que dE00 representa una distancia
	// geométrica (que va de 0 a aproximadamente 185) en el espacio CIELAB.
	Exit(sqrt(l * l + h * h + c * c + c * h * r_t));
end;

//    Proyecto GitHub : https://github.com/michel-leonard/ciede2000-color-matching
//   Pruebas en línea : https://michel-leonard.github.io/ciede2000-color-matching

// L1 = 40.9   a1 = 22.7   b1 = 4.1
// L2 = 41.1   a2 = 28.1   b2 = -3.6
// CIE ΔE00 = 5.6213040434 (Bruce Lindbloom, Netflix’s VMAF, ...)
// CIE ΔE00 = 5.6212902503 (Gaurav Sharma, OpenJDK, ...)
// Desviación entre implementaciones ≈ 1.4e-5

// Consulte los comentarios del código fuente para pasar de una de estas variantes de implementación ΔE*00 a la otra.

Parámetros k_l, k_c y k_h

Los parámetros k_l, k_c y k_h en CIEDE2000 son factores de ponderación aplicados a los términos brillo (ΔL*), croma (ΔC*) y tono (ΔH*). Se definen como constantes en el código fuente. Su valor por defecto es 1, que corresponde a las condiciones de visualización estándar recomendadas por la Comisión Internacional de Iluminación (CIE). En la práctica, puede ser necesario ajustar estos coeficientes para reflejar condiciones específicas: por ejemplo, k_l = 2 se utiliza a veces para dar más peso a las diferencias de brillo (algo habitual en la industria textil), mientras que k_c o k_h pueden reducirse para aumentar la tolerancia a las variaciones de saturación o tono, según los requisitos. Según el contexto, estos coeficientes suelen oscilar entre 0,5 y 2.

Precisión y fiabilidad del código fuente

La diferencia entre la formulación académica de Sharma y la simplificada de Lindbloom no supera ±0,0003 en el ΔE2000 final. Esto corresponde a la diferencia que suele medirse entre dos implementaciones de 32 bits y es imperceptible para el ojo humano. Nuestras implementaciones de 64 bits, todas coherentes entre sí, garantizan al menos 10 decimales correctos, por lo que la elección de una formulación sobre la otra es un detalle técnico. La fórmula por defecto de esta página es la que se presenta con más frecuencia en la comunidad, es ligeramente más fácil de vectorizar.

✎ Si observáis que los comentarios del código fuente no coinciden con los comentarios en inglés, por favor, informad al autor de la página para que pueda corregirlo.

¿Cómo se convierten los colores RGB a L*a*b*?

Vaya a la página AWK, C, Dart, Java, JavaScript, Kotlin, Lua, PHP, Python, Ruby o Rust, donde ya está implementado dicho conversor (que utiliza el iluminante D65), además de la función de comparación de colores.

Rangos de valores en CIELAB e interpretación del ΔE2000

En el espacio de color CIELAB, el componente L* representa la luminosidad y suele variar de 0 (negro) a 100 (blanco). Los componentes a* y b* definen los ejes de color: a* va del verde al rojo, y b* del azul al amarillo. En la práctica, a* y b* se encuentran normalmente entre -128 y +127, aunque pueden superar ligeramente estos límites según la conversión de color.

ΔE2000 (CIEDE2000) cuantifica la diferencia perceptible entre dos colores: 0 significa que son idénticos, y valores más altos (hasta aproximadamente 185 en casos extremos) indican una diferencia más notable. Por ejemplo, un ΔE2000 alrededor de 5 indica colores cercanos, mientras que alrededor de 15 indica colores claramente distintos.

Ejemplo de uso en Pascal

// Calculate ΔE*00 between two colors in L*a*b* space
var
  l1, a1, b1, l2, a2, b2, deltaE: Double;
begin
  l1 := 31.8; a1 := 22.9; b1 := 4.8;
  l2 := 30.2; a2 := 18.7; b2 := -3.7;

  deltaE := ciede_2000(l1, a1, b1, l2, a2, b2);
  writeln('CIEDE2000 = ', deltaE:0:10);
end.

// .................................................. This shows a ΔE2000 of 6.1884550095
// As explained in the comments, compliance with Gaurav Sharma would display 6.1884708040

Los resultados de las pruebas

El controlador escrito en lenguaje C99, con 250 pruebas estáticas precisas, ha demostrado que esta función Pascal es interoperable con la función CIEDE2000 disponible en otros lenguajes de programación.

CIEDE2000 Verification Summary :
  First Verified Line : 89.9,44,33,7,-75.04,-57,120.27117304507197559
             Duration : 33.38 s
            Successes : 10000000
               Errors : 0
      Average Delta E : 62.9452
    Average Deviation : 1.4059798381094168e-14
    Maximum Deviation : 3.4106051316484809e-13

Archivos para descargar

Siéntase libre de utilizar estos archivos puestos a disposición por Michel, incluso con fines comerciales.

Comunidad

¿Qué opina de este código fuente o de CIEDE2000? Su opinión es importante para nosotros. El libro de visitas ya contiene 9 mensajes - incluyendo 1 en español. Eche un vistazo y comparta su opinión.