Implementación de CIEDE2000 en AWK

Esta página presenta una implementación de referencia de la fórmula de diferencia de color CIEDE2000 escrita en el lenguaje de programación AWK. Si desea garantizar una compatibilidad perfecta (hasta el décimo decimal) con algunas implementaciones de terceros, es posible que tenga que modificar los comentarios del código fuente. Para facilitarlo, el siguiente enlace automatiza esta operación.

La función ΔE2000 en AWK

Consideremos la más común y académica (Sharma, 2005) de las dos formulaciones.

# Esta función escrita en AWK es de dominio público y no
# está afiliada a la CIE (Comisión Internacional de Iluminación).

BEGIN {
	# k_l, k_c y k_h son factores paramétricos a ajustar según
	# sus necesidades de visualización (texturas, fondos).
	k_l = k_c = k_h = 1.0
	FS = ","
	M_PI = 3.14159265358979323846264338328
}

{
	# Recibe un fichero CSV de 6 columnas a través de una tubería y añade la diferencia de color en la última columna.
	sub(/\r$/, "") # Normalizar el final de las líneas de Windows para Unix.
	printf("%s,%.15g\n", $0, ciede_2000($1, $2, $3, $4, $5, $6))
}

# La implementación clásica de CIEDE2000 que recibe dos colores L*a*b* y devuelve su diferencia.
# El componente "L" varía de 0 a 100. "a" y "b" normalmente se proyectan entre -128 y 127.
function ciede_2000(l_1, a_1, b_1, l_2, a_2, b_2) {
	# Ejecuta el cálculo de diferencia de color CIEDE2000 en AWK.
	n = (sqrt(a_1 * a_1 + b_1 * b_1) + sqrt(a_2 * a_2 + b_2 * b_2)) * 0.5
	n = n * n * n * n * n * n * n
	# Un factor que implica la croma elevada a la potencia 7,
	# diseñado para tener más en cuenta la influencia de la croma.
	n = 1.0 + 0.5 * (1.0 - sqrt(n / (n + 6103515625.0)))
	# Aplicación del factor de corrección de la croma para compensar su no linealidad.
	c_1 = sqrt(a_1 * a_1 * n * n + b_1 * b_1)
	c_2 = sqrt(a_2 * a_2 * n * n + b_2 * b_2)
	# La función atan2 es preferible a atan porque calcula el ángulo de un
	# punto (x, y) en todos los cuadrantes, teniendo en cuenta el signo de x e y.
	h_1 = atan2(b_1, a_1 * n)
	h_2 = atan2(b_2, a_2 * n)
	if (h_1 < 0.0) h_1 += 2.0 * M_PI
	h_2 += 2.0 * M_PI * (h_2 < 0.0)
	n = h_2 < h_1 ? h_1 - h_2 : h_2 - h_1
	# Evita que la rama dependa del RoundingMode del lenguaje de programación.
	if (M_PI - 1E-14 < n && n < M_PI + 1E-14)
		n = M_PI
	# Cuando los ángulos de tono se encuentran en diferentes cuadrantes,
	# la media aritmética simple puede dar un ángulo incorrecto, las
	# líneas siguientes aplican la corrección angular necesaria.
	h_m = (h_1 + h_2) * 0.5
	h_d = (h_2 - h_1) * 0.5
	if (M_PI < n) {
		h_d += M_PI
		# 📜 La formulación de Sharma no utiliza la línea siguiente, sino la que le sigue.
		# Nota: estas dos variantes sólo difieren en ±0,0003 en la diferencia de color final.
		h_m += M_PI
		# h_m += ((h_m < M_PI) - (M_PI <= h_m)) * M_PI
	}
	p = 36.0 * h_m - 55.0 * M_PI
	n = (c_1 + c_2) * 0.5
	n = n * n * n * n * n * n * n
	# El término de corrección de la rotación del tono mejora la precisión
	# del algoritmo, especialmente cuando la comparación se refiere a azules.
	r_t = -2.0 * sqrt(n / (n + 6103515625.0)) \
			* sin(M_PI / 3.0 * exp(p * p / (-25.0 * M_PI * M_PI)))
	n = (l_1 + l_2) * 0.5
	n = (n - 50.0) * (n - 50.0)
	#  Luminosidad .
	l = (l_2 - l_1) / (k_l * (1.0 + 0.015 * n / sqrt(20.0 + n)))
	# Estos coeficientes se utilizan para modular la influencia de
	# los componentes armónicos en el cálculo de la diferencia de tono.
	t = 1.0	+ 0.24 * sin(2.0 * h_m + M_PI * 0.5) \
		+ 0.32 * sin(3.0 * h_m + 8.0 * M_PI / 15.0) \
		- 0.17 * sin(h_m + M_PI / 3.0) \
		- 0.20 * sin(4.0 * h_m + 3.0 * M_PI / 20.0)
	n = c_1 + c_2
	# Tono.
	h = 2.0 * sqrt(c_1 * c_2) * sin(h_d) / (k_h * (1.0 + 0.0075 * n * t))
	# Croma.
	c = (c_2 - c_1) / (k_c * (1.0 + 0.0225 * n))
	# Devolver la raíz cuadrada garantiza que dE00 representa una distancia
	# geométrica (que va de 0 a aproximadamente 185) en el espacio CIELAB.
	return sqrt(l * l + h * h + c * c + c * h * r_t)
}

#    Proyecto GitHub : https://github.com/michel-leonard/ciede2000-color-matching
#   Pruebas en línea : https://michel-leonard.github.io/ciede2000-color-matching

# L1 = 57.7   a1 = 17.2   b1 = -2.8
# L2 = 56.2   a2 = 22.9   b2 = 4.2
# CIE ΔE00 = 5.8591939826 (Bruce Lindbloom, Netflix’s VMAF, ...)
# CIE ΔE00 = 5.8592116089 (Gaurav Sharma, OpenJDK, ...)
# Desviación entre implementaciones ≈ 1.8e-5

# Consulte los comentarios del código fuente para pasar de una de estas variantes de implementación ΔE*00 a la otra.

Parámetros k_l, k_c y k_h

Los parámetros k_l, k_c y k_h de la fórmula CIEDE2000 son factores de ponderación que se aplican a los componentes de luminosidad (ΔL*), croma (ΔC*) y tono (ΔH*), respectivamente. En el código fuente, se definen como constantes cuyo valor por defecto es 1, lo que se corresponde con las condiciones de observación estándar establecidas por la Comisión Internacional de Iluminación (CIE). En la práctica, puede ser necesario ajustar estos coeficientes para reflejar condiciones específicas: por ejemplo, k_l = 2 se utiliza a veces para dar más peso a las diferencias de brillo (algo habitual en la industria textil), mientras que k_c o k_h pueden reducirse para aumentar la tolerancia a las variaciones de saturación o tono. En resumen, estos coeficientes suelen oscilar entre 0,5 y 2, siendo 1 el valor más habitual.

Precisión y fiabilidad del código fuente

La diferencia entre la formulación académica de Sharma y la simplificada de Lindbloom no supera ±0,0003 en el ΔE2000 final. La implementación que aquí se presenta es de 64 bits y garantiza una precisión de más de 10 decimales; por lo tanto, la elección de una formulación en lugar de otra es un detalle técnico. En la parte superior de esta página, puedes elegir entre las dos formulaciones; la que se muestra actualmente es la formulación simplificada.

¿Cómo determinar si una implementación determinada de CIEDE2000 es académica o simplificada?

• Evalúa ciede_2000(56.6, 43.6, 41.1, 68.4, 9.4, -8.6)
• Si el resultado es 30.0001, entonces es del tipo académico (como Sharma, OpenJDK, etc.)
• Si el resultado es 29.9999, entonces es del tipo simplificado (como Lindbloom, Netflix VMAF, etc.)

¿Cómo se convierten los colores RGB a L*a*b*?

Deberá utilizar el espacio de color intermedio XYZ para la conversión y, si necesita ayuda, al final de esta página encontrará el código fuente (que utiliza el punto blanco D65 formalizado en 1964).

Rangos de valores en CIELAB e interpretación del ΔE2000

En el espacio de color CIELAB, el componente L* representa la luminosidad y suele variar de 0 (negro) a 100 (blanco). Los componentes a* y b* definen los ejes de color: a* va del verde al rojo, y b* del azul al amarillo. En la práctica, los valores de a* y b* casi siempre se limitan a un intervalo comprendido entre -128 y +127, aunque la norma no establece un límite oficial para estos dos componentes.

ΔE2000 (CIEDE2000) cuantifica la diferencia perceptible entre dos colores: 0 significa que son idénticos, y valores más altos (hasta 185 y más) indican una diferencia más notable. Por ejemplo, un ΔE2000 alrededor de 5 indica colores cercanos, mientras que alrededor de 15 indica colores claramente distintos. Cuando el valor ΔE2000 supera 40, los colores comparados ya casi no tienen nada en común, y no podemos extraer de ellos información precisa.

Ejemplo de uso en AWK

awk -f ciede-2000.awk < samples.csv

Los resultados de las pruebas

Nuestro programa de pruebas, escrito en C99, incluye 250 pruebas estáticas precisas. Estas pruebas garantizan que tus cálculos se realizarán sin errores, incluso en casos límite críticos, por ejemplo, cuando la función arcotangente devuelve un valor matemáticamente indefinido. Los resultados muestran que esta función CIEDE2000 en AWK es interoperable con los 41 demás lenguajes de programación que ofrecemos.

CIEDE2000 Verification Summary :
  First Verified Line : 69.47,-24,-36,20,-36.8,-94.1,48.6133314128157
             Duration : 56.73 s
            Successes : 10000000
               Errors : 0
      Average Delta E : 62.9396
    Average Deviation : 4.5856684738332374e-14
    Maximum Deviation : 5.6843418860808015e-13

Archivos para descargar

Siéntase libre de utilizar estos archivos puestos a disposición por Michel, incluso con fines comerciales.

Comunidad

¿Qué opina de este código fuente o de CIEDE2000? Su opinión es importante para nosotros. El libro de visitas ya contiene 9 mensajes - incluyendo 1 en español. Eche un vistazo y comparta su opinión.