Implementación de CIEDE2000 en Fortran

Esta página presenta una implementación de referencia de la fórmula de diferencia de color CIEDE2000 en Fortran. Si desea garantizar una compatibilidad perfecta (hasta el décimo decimal) con algunas implementaciones de terceros, es posible que tenga que modificar los comentarios del código fuente. Para facilitarlo, el siguiente enlace automatiza esta operación.

La función ΔE2000 en Fortran

Consideremos la más común y académica (Sharma, 2005) de las dos formulaciones.

! Esta función escrita en Fortran es de dominio público y no
! está afiliada a la CIE (Comisión Internacional de Iluminación).

module ciede_2000_module
  use iso_fortran_env, only: real64
  implicit none
  private
  public :: ciede_2000
  real(kind=real64), parameter :: M_PI = 3.14159265358979323846264338328_real64
    ! k_l, k_c y k_h son factores paramétricos a ajustar según
    ! sus necesidades de visualización (texturas, fondos).
  real(kind=real64), parameter :: k_l = 1.0_real64, k_c = 1.0_real64, k_h = 1.0_real64
contains
  ! La implementación clásica de CIEDE2000 que recibe dos colores L*a*b* y devuelve su diferencia.
  ! El componente "L" varía de 0 a 100. "a" y "b" normalmente se proyectan entre -128 y 127.
  function ciede_2000(l_1, a_1, b_1, l_2, a_2, b_2) result(delta_e)
    implicit none
    real(kind=real64), intent(in) :: l_1, a_1, b_1, l_2, a_2, b_2
    real(kind=real64) :: n, c_1, c_2, h_1, h_2, h_m, h_d, p, r_t, l, t, h, c, delta_e
    ! Ejecuta el cálculo de diferencia de color CIEDE2000 en Fortran.
    n = (sqrt(a_1 * a_1 + b_1 * b_1) + sqrt(a_2 * a_2 + b_2 * b_2)) * 0.5_real64
    n = n * n * n * n * n * n * n
    ! Un factor que implica la croma elevada a la potencia 7,
    ! diseñado para tener más en cuenta la influencia de la croma.
    n = 1.0_real64 + 0.5_real64 * (1.0_real64 - sqrt(n / (n + 6103515625.0_real64)))
    ! Aplicación del factor de corrección de la croma para compensar su no linealidad.
    c_1 = sqrt(a_1 * a_1 * n * n + b_1 * b_1)
    c_2 = sqrt(a_2 * a_2 * n * n + b_2 * b_2)
    ! La función atan2 es preferible a atan porque calcula el ángulo de un
    ! punto (x, y) en todos los cuadrantes, teniendo en cuenta el signo de x e y.
    h_1 = atan2(b_1, a_1 * n)
    h_2 = atan2(b_2, a_2 * n)
    if (h_1 < 0.0_real64) h_1 = h_1 + 2.0_real64 * M_PI
    if (h_2 < 0.0_real64) h_2 = h_2 + 2.0_real64 * M_PI
    n = abs(h_2 - h_1)
    ! Evita que la rama dependa del RoundingMode del lenguaje de programación.
    if (M_PI - 0.00000000000001_real64 < n .and. n < M_PI + 0.00000000000001_real64) n = M_PI
    ! Cuando los ángulos de tono se encuentran en diferentes cuadrantes,
    ! la media aritmética simple puede dar un ángulo incorrecto, las
    ! líneas siguientes aplican la corrección angular necesaria.
    h_m = (h_1 + h_2) * 0.5_real64
    h_d = (h_2 - h_1) * 0.5_real64
    if (M_PI < n) then
      h_d = h_d + M_PI
      ! 📜 La formulación de Sharma no utiliza la línea siguiente, sino la que le sigue.
      ! Nota: estas dos variantes sólo difieren en ±0,0003 en la diferencia de color final.
      h_m = h_m + M_PI
      ! h_m = h_m + MERGE(M_PI, -M_PI, h_m < M_PI)
    endif
    p = 36.0_real64 * h_m - 55.0_real64 * M_PI
    n = (c_1 + c_2) * 0.5_real64
    n = n * n * n * n * n * n * n
    ! El término de corrección de la rotación del tono mejora la precisión
    ! del algoritmo, especialmente cuando la comparación se refiere a azules.
    r_t = -2.0_real64 * sqrt(n / (n + 6103515625.0_real64)) &
                        * sin(M_PI / 3.0_real64 * exp(p * p / (-25.0_real64 * M_PI * M_PI)))
    n = (l_1 + l_2) * 0.5_real64
    n = (n - 50.0_real64) * (n - 50.0_real64)
    !  Luminosidad .
    l = (l_2 - l_1) / (k_l * (1.0_real64 + 0.015_real64 * n / sqrt(20.0_real64 + n)))
    ! Estos coeficientes se utilizan para modular la influencia de
    ! los componentes armónicos en el cálculo de la diferencia de tono.
    t = 1.0_real64   + 0.24_real64 * sin(2.0_real64 * h_m + M_PI / 2.0_real64) &
                     + 0.32_real64 * sin(3.0_real64 * h_m + 8.0_real64 * M_PI / 15.0_real64) &
                     - 0.17_real64 * sin(h_m + M_PI / 3.0_real64) &
                     - 0.20_real64 * sin(4.0_real64 * h_m + 3.0_real64 * M_PI / 20.0_real64)
    n = c_1 + c_2
    ! Tono.
    h = 2.0_real64 * sqrt(c_1 * c_2) * sin(h_d) / (k_h * (1.0_real64 + 0.0075_real64 * n * t))
    ! Croma.
    c = (c_2 - c_1) / (k_c * (1.0_real64 + 0.0225_real64 * n))
    ! Devolver la raíz cuadrada garantiza que dE00 representa una distancia
    ! geométrica (que va de 0 a aproximadamente 185) en el espacio CIELAB.
    delta_e = sqrt(l * l + h * h + c * c + c * h * r_t)
  end function ciede_2000
end module ciede_2000_module

!    Proyecto GitHub : https://github.com/michel-leonard/ciede2000-color-matching
!   Pruebas en línea : https://michel-leonard.github.io/ciede2000-color-matching

! L1 = 68.5   a1 = 18.1   b1 = 3.6
! L2 = 70.2   a2 = 23.8   b2 = -4.0
! CIE ΔE00 = 6.1142357448 (Bruce Lindbloom, Netflix’s VMAF, ...)
! CIE ΔE00 = 6.1142186799 (Gaurav Sharma, OpenJDK, ...)
! Desviación entre implementaciones ≈ 1.7e-5

! Consulte los comentarios del código fuente para pasar de una de estas variantes de implementación ΔE*00 a la otra.

Parámetros k_l, k_c y k_h

Los parámetros k_l, k_c y k_h de la fórmula CIEDE2000 son factores de ponderación que se aplican a los componentes de luminosidad (ΔL*), croma (ΔC*) y tono (ΔH*), respectivamente. En el código fuente, se definen como constantes cuyo valor por defecto es 1, lo que se corresponde con las condiciones de observación estándar establecidas por la Comisión Internacional de Iluminación (CIE). En la práctica, puede ser necesario ajustar estos coeficientes para reflejar condiciones específicas: por ejemplo, k_l = 2 se utiliza a veces para dar más peso a las diferencias de brillo (algo habitual en la industria textil), mientras que k_c o k_h pueden reducirse para aumentar la tolerancia a las variaciones de saturación o tono. En resumen, estos coeficientes suelen oscilar entre 0,5 y 2, siendo 1 el valor más habitual.

Precisión y fiabilidad del código fuente

La diferencia entre la formulación académica de Sharma y la simplificada de Lindbloom no supera ±0,0003 en el ΔE2000 final. Esto corresponde a la diferencia que suele medirse entre dos implementaciones de 32 bits y es imperceptible para el ojo humano. La implementación que se presenta en esta página es de 64 bits y garantiza al menos 10 decimales correctos; por lo tanto, la elección de una formulación en lugar de otra es un detalle técnico. La fórmula por defecto de esta página es la que se presenta con más frecuencia en la comunidad, es ligeramente más fácil de vectorizar.

✎ Si observáis que los comentarios del código fuente no coinciden con los comentarios en inglés, por favor, informad al autor de la página para que pueda corregirlo.

¿Cómo se convierten los colores RGB a L*a*b*?

Vaya a la página AWK, C, Dart, Java, JavaScript, Kotlin, Lua, PHP, Python, Ruby o Rust, donde ya está implementado dicho conversor (que utiliza el iluminante D65), además de la función de comparación de colores.

Rangos de valores en CIELAB e interpretación del ΔE2000

En el espacio de color CIELAB, el componente L* representa la luminosidad y suele variar de 0 (negro) a 100 (blanco). Los componentes a* y b* definen los ejes de color: a* va del verde al rojo, y b* del azul al amarillo. En la práctica, los valores de a* y b* casi siempre se limitan a un intervalo comprendido entre -128 y +127, aunque la norma no establece un límite oficial para estos dos componentes.

ΔE2000 (CIEDE2000) cuantifica la diferencia perceptible entre dos colores: 0 significa que son idénticos, y valores más altos (hasta 185 y más) indican una diferencia más notable. Por ejemplo, un ΔE2000 alrededor de 5 indica colores cercanos, mientras que alrededor de 15 indica colores claramente distintos. Cuando el valor ΔE2000 supera 40, los colores comparados ya casi no tienen nada en común, y no podemos extraer de ellos información precisa.

Ejemplo de uso en Fortran

! Compute the Delta E (CIEDE2000) color difference between two L*a*b* colors in Fortran

! Color 1: l1 = 89.0   a1 = 33.3   b1 = -1.7
! Color 2: l2 = 89.2   a2 = 38.4   b2 = 2.2

delta_e = ciede_2000(l1, a1, b1, l2, a2, b2)
print '(F0.10)', delta_e

! .................................................. This shows a ΔE2000 of 2.9929564263
! As explained in the comments, compliance with Gaurav Sharma would display 2.9929700654

Los resultados de las pruebas

Nuestro programa de pruebas, escrito en C99, incluye 250 pruebas estáticas precisas. Los resultados muestran que esta función de CIEDE2000 en Fortran es interoperable con los otros 41 lenguajes de programación.

CIEDE2000 Verification Summary :
  First Verified Line : 24,122.6,117,21,-40.999999999847,-46,81.762663548041459
             Duration : 41.38 s
            Successes : 10000000
               Errors : 0
      Average Delta E : 63.2338
    Average Deviation : 4.6e-15
    Maximum Deviation : 1.1e-13

Archivos para descargar

Siéntase libre de utilizar estos archivos puestos a disposición por Michel, incluso con fines comerciales.

Comunidad

¿Qué opina de este código fuente o de CIEDE2000? Su opinión es importante para nosotros. El libro de visitas ya contiene 9 mensajes - incluyendo 1 en español. Eche un vistazo y comparta su opinión.