Implementação do CIEDE2000 em Elixir

Esta página apresenta uma implementação de referência da fórmula de diferença de cor CIEDE2000 em Elixir. Se quiser assegurar uma compatibilidade perfeita (até à décima casa decimal) com algumas implementações de terceiros, poderá ter de modificar os comentários no código fonte. Para facilitar isto, a seguinte ligação automatiza esta operação.

A função ΔE2000 em Elixir

Consideremos a mais comum e académica (Sharma, 2005) das duas formulações.

# This function written in Elixir is not affiliated with the CIE (International Commission on Illumination),
# and is released into the public domain. It is provided "as is" without any warranty, express or implied.

# The classic CIE ΔE2000 implementation, which operates on two L*a*b* colors, and returns their difference.
# "l" ranges from 0 to 100, while "a" and "b" are unbounded and commonly clamped to the range of -128 to 127.
def ciede_2000(l_1, a_1, b_1, l_2, a_2, b_2)
	when is_float(l_1) and is_float(a_1)  and is_float(b_1) and is_float(l_2) and is_float(a_2)  and is_float(b_2) do
	# Working in Elixir with the CIEDE2000 color-difference formula.
	# k_l, k_c, k_h are parametric factors to be adjusted according to
	# different viewing parameters such as textures, backgrounds...
	{k_l, k_c, k_h, m_pi} = {1.0, 1.0, 1.0, :math.pi()}
	n = (:math.sqrt(a_1 * a_1 + b_1 * b_1) + :math.sqrt(a_2 * a_2 + b_2 * b_2)) * 0.5
	n = n * n * n * n * n * n * n
	# A factor involving chroma raised to the power of 7 designed to make
	# the influence of chroma on the total color difference more accurate.
	n = 1.0 + 0.5 * (1.0 - :math.sqrt(n / (n + 6103515625.0)))
	# Application of the chroma correction factor.
	c_1 = :math.sqrt(a_1 * a_1 * n * n + b_1 * b_1)
	c_2 = :math.sqrt(a_2 * a_2 * n * n + b_2 * b_2)
	# atan2 is preferred over atan because it accurately computes the angle of
	# a point (x, y) in all quadrants, handling the signs of both coordinates.
	h_1 = :math.atan2(b_1, a_1 * n)
	h_2 = :math.atan2(b_2, a_2 * n)
	h_1 = if h_1 < 0.0, do: h_1 + 2.0 * m_pi, else: h_1
	h_2 = if h_2 < 0.0, do: h_2 + 2.0 * m_pi, else: h_2
	n = abs(h_2 - h_1)
	# Cross-implementation consistent rounding.
	n = if m_pi - 1.0E-14 < n and n < m_pi + 1.0E-14, do: m_pi, else: n
	# When the hue angles lie in different quadrants, the straightforward
	# average can produce a mean that incorrectly suggests a hue angle in
	# the wrong quadrant, the next lines handle this issue.
	h_m = (h_1 + h_2) * 0.5
	h_d = (h_2 - h_1) * 0.5
	h_d = if m_pi < n, do: h_d + m_pi, else: h_d
	# 📜 Sharma’s formulation doesn’t use the next line, but the one after it,
	# and these two variants differ by ±0.0003 on the final color differences.
	h_m = if m_pi < n, do: h_m + m_pi, else: h_m
	# h_m = if m_pi < n, do: (if h_m < m_pi, do: h_m + m_pi, else: h_m - m_pi), else: h_m
	p = 36.0 * h_m - 55.0 * m_pi
	n = (c_1 + c_2) * 0.5
	n = n * n * n * n * n * n * n
	# The hue rotation correction term is designed to account for the
	# non-linear behavior of hue differences in the blue region.
	r_t = -2.0 * :math.sqrt(n / (n + 6103515625.0)) *
		:math.sin(m_pi / 3.0 * :math.exp(p * p / (-25.0 * m_pi * m_pi)))
	n = (l_1 + l_2) * 0.5
	n = (n - 50.0) * (n - 50.0)
	# Lightness.
	l = (l_2 - l_1) / (k_l * (1.0 + 0.015 * n / :math.sqrt(20.0 + n)))
	# These coefficients adjust the impact of different harmonic
	# components on the hue difference calculation.
	t = 1.0 +	0.24 * :math.sin(2.0 * h_m + m_pi / 2.0) +
			0.32 * :math.sin(3.0 * h_m + 8.0 * m_pi / 15.0) -
			0.17 * :math.sin(h_m + m_pi / 3.0) -
			0.20 * :math.sin(4.0 * h_m + 3.0 * m_pi / 20.0)
	n = c_1 + c_2
	# Hue.
	h = 2.0 * :math.sqrt(c_1 * c_2) * :math.sin(h_d) / (k_h * (1.0 + 0.0075 * n * t))
	# Chroma.
	c = (c_2 - c_1) / (k_c * (1.0 + 0.0225 * n))
	# Returning the square root ensures that dE00 accurately reflects the
	# geometric distance in color space, which can range from 0 to around 185.
	:math.sqrt(l * l + h * h + c * c + c * h * r_t)
end

# GitHub Project : https://github.com/michel-leonard/ciede2000-color-matching
#   Online Tests : https://michel-leonard.github.io/ciede2000-color-matching

# L1 = 80.1   a1 = 20.9   b1 = 4.3
# L2 = 82.2   a2 = 26.1   b2 = -3.9
# CIE ΔE00 = 6.1587582595 (Bruce Lindbloom, Netflix’s VMAF, ...)
# CIE ΔE00 = 6.1587450086 (Gaurav Sharma, OpenJDK, ...)
# Deviation between implementations ≈ 1.3e-5

# See the source code comments for easy switching between these two widely used ΔE*00 implementation variants.

Parâmetros k_l, k_c e k_h

Os parâmetros k_l, k_c e k_h na fórmula CIEDE2000 são factores de ponderação aplicados aos componentes de brilho (ΔL*), croma (ΔC*) e matiz (ΔH*), respetivamente. São definidos como constantes no código fonte. No código-fonte, são definidos como constantes com um valor por defeito de 1, que corresponde às condições de observação padrão estabelecidas pela Comissão Internacional da Iluminação (CIE). Na prática, pode ser necessário ajustar estes coeficientes para refletir condições específicas: por exemplo, k_l = 2 é por vezes utilizado para dar mais peso a diferenças de brilho (uma ocorrência comum na indústria têxtil), enquanto k_c ou k_h podem ser reduzidos para aumentar a tolerância a variações de saturação ou matiz. Em resumo, estes coeficientes variam normalmente entre 0,5 e 2, sendo 1 o valor mais comum.

Precisão e fiabilidade do código fonte

A diferença entre a formulação académica de Sharma e a formulação simplificada de Lindbloom não excede ±0,0003 no ΔE2000 final. A implementação aqui apresentada é de 64 bits e garante uma precisão superior a 10 casas decimais; a escolha de uma formulação em detrimento de outra é, portanto, um pormenor técnico. No topo desta página, pode escolher entre as duas formulações; a que está atualmente a ser apresentada é a formulação simplificada.

Como determinar se uma determinada implementação do CIEDE2000 é acadêmica ou simplificada?

• Avaliem ciede_2000(27.5, 24.6, 9.2, 15.7, 56.6, -18.5) com precisão
• Se o resultado for 19.999944, trata-se do tipo acadêmico (como Sharma, OpenJDK, etc.)
• Se o resultado for 20.000002, trata-se do tipo simplificado (como Lindbloom, Netflix VMAF, etc.)

Como é que se convertem cores RGB em L*a*b*?

Vá para a página AWK, C, Dart, Java, JavaScript, Kotlin, Lua, PHP, Python, Ruby ou Rust onde esse conversor (utilizando o iluminante D65) já está implementado para além da função de comparação de cores.

Intervalos de valores no CIELAB e interpretação do ΔE2000

No espaço de cor CIELAB, o componente L* representa a luminosidade e normalmente varia de 0 (preto) a 100 (branco). Os componentes a* e b* representam os eixos de cor: a* vai do verde ao vermelho, enquanto b* vai do azul ao amarelo. Na prática, os valores de a* e b* estão quase sempre limitados a um intervalo entre -128 e +127, embora a norma não especifique um limite oficial para estes dois componentes.

ΔE2000 (CIEDE2000) mede a diferença perceptível entre duas cores: 0 significa cores idênticas, e valores maiores (até 185 e mais) indicam uma diferença mais significativa. Por exemplo, um valor ΔE2000 em torno de 5 indica cores próximas, enquanto em torno de 15 indica cores claramente diferentes. Quando o valor ΔE2000 ultrapassa 40, as cores comparadas já não têm praticamente nada em comum, e não é possível obter informações precisas a partir delas.

Exemplo de utilização em Elixir

# Compute the Delta E (CIEDE2000) color difference between two L*a*b* colors in Elixir

{ l1, a1, b1 } = { 57.1, 17.1, 4.9  }
{ l2, a2, b2 } = { 59.2, 10.9, -3.1 }

delta_e = ciede_2000(l1, a1, b1, l2, a2, b2)
IO.puts("#{delta_e}")

# .................................................. This shows a ΔE2000 of 7.5254510508
# As explained in the comments, compliance with Gaurav Sharma would display 7.5254660817

Resultados dos testes

O nosso programa de testes, escrito em C99, inclui 250 testes estáticos precisos. Os resultados mostram que esta função do CIEDE2000 em Elixir é interoperável com as outras 41 linguagens de programação.

CIEDE2000 Verification Summary :
  First Verified Line : 27,-123,101,44,-30,122,29.989372817453113
             Duration : 157.82 s
            Successes : 10000000
               Errors : 0
      Average Delta E : 63.2072
    Average Deviation : 3.9e-15
    Maximum Deviation : 1.1e-13

Ficheiros para descarregar

Pode utilizar livremente estes ficheiros disponibilizados pelo Michel, mesmo para fins comerciais.

Comunidade

O que pensa deste código fonte ou do CIEDE2000? A sua opinião é importante para nós! O livro de visitas já contém 9 mensagens - incluindo 1 em português. Dê uma vista de olhos e partilhe a sua opinião.