Implementazione di CIEDE2000 in Julia

Questa pagina presenta un’implementazione di riferimento della formula della differenza di colore CIEDE2000 in Julia. Se si vuole garantire la perfetta compatibilità (con la decima cifra decimale) con alcune implementazioni di terze parti, potrebbe essere necessario modificare i commenti nel codice sorgente. Per facilitare questa operazione, il seguente link la automatizza.

La funzione ΔE2000 in Julia

Consideriamo la più comune e accademica (Sharma, 2005) delle due formulazioni.

# This function written in Julia is not affiliated with the CIE (International Commission on Illumination),
# and is released into the public domain. It is provided "as is" without any warranty, express or implied.

using Base.MathConstants
using LinearAlgebra

# The classic CIE ΔE2000 implementation, which operates on two L*a*b* colors, and returns their difference.
# "l" ranges from 0 to 100, while "a" and "b" are unbounded and commonly clamped to the range of -128 to 127.
function ciede_2000(l_1::Float64, a_1::Float64, b_1::Float64, l_2::Float64, a_2::Float64, b_2::Float64)::Float64
	# Working in Julia with the CIEDE2000 color-difference formula.
	# k_l, k_c, k_h are parametric factors to be adjusted according to
	# different viewing parameters such as textures, backgrounds...
	k_l = k_c = k_h = 1.0
	n = (sqrt(a_1 * a_1 + b_1 * b_1) + sqrt(a_2 * a_2 + b_2 * b_2)) * 0.5
	n = n * n * n * n * n * n * n
	# A factor involving chroma raised to the power of 7 designed to make
	# the influence of chroma on the total color difference more accurate.
	n = 1.0 + 0.5 * (1.0 - sqrt(n / (n + 6103515625.0)))
	# Application of the chroma correction factor.
	c_1 = sqrt(a_1 * a_1 * n * n + b_1 * b_1)
	c_2 = sqrt(a_2 * a_2 * n * n + b_2 * b_2)
	# atan2 is preferred over atan because it accurately computes the angle of
	# a point (x, y) in all quadrants, handling the signs of both coordinates.
	h_1 = atan(b_1, a_1 * n)
	h_2 = atan(b_2, a_2 * n)
	h_1 += 2.0 * π * (h_1 < 0.0)
	h_2 += 2.0 * π * (h_2 < 0.0)
	n = abs(h_2 - h_1)
	# Cross-implementation consistent rounding.
	if π - 1E-14 < n && n < π + 1E-14
		n = π
	end
	# When the hue angles lie in different quadrants, the straightforward
	# average can produce a mean that incorrectly suggests a hue angle in
	# the wrong quadrant, the next lines handle this issue.
	h_m = (h_1 + h_2) * 0.5
	h_d = (h_2 - h_1) * 0.5
	if π < n
		h_d += π
		# 📜 Sharma’s formulation doesn’t use the next line, but the one after it,
		# and these two variants differ by ±0.0003 on the final color differences.
		h_m += π
		# h_m += h_m < π ? π : -π
	end
	p = 36.0 * h_m - 55.0 * π
	n = (c_1 + c_2) * 0.5
	n = n * n * n * n * n * n * n
	# The hue rotation correction term is designed to account for the
	# non-linear behavior of hue differences in the blue region.
	r_t = -2.0 * sqrt(n / (n + 6103515625.0)) *
			sin(π / 3.0 * exp(p * p / (-25.0 * π * π)))
	n = (l_1 + l_2) * 0.5
	n = (n - 50.0) * (n - 50.0)
	# Lightness.
	l = (l_2 - l_1) / (k_l * (1.0 + 0.015 * n / sqrt(20.0 + n)))
	# These coefficients adjust the impact of different harmonic
	# components on the hue difference calculation.
	t = 1.0	+ 0.24 * sin(2.0 * h_m + π * 0.5) +
		0.32 * sin(3.0 * h_m + 8.0 * π / 15.0) -
		0.17 * sin(h_m + π / 3.0) -
		0.20 * sin(4.0 * h_m + 3.0 * π / 20.0)
	n = c_1 + c_2
	# Hue.
	h = 2.0 * sqrt(c_1 * c_2) * sin(h_d) / (k_h * (1.0 + 0.0075 * n * t))
	# Chroma.
	c = (c_2 - c_1) / (k_c * (1.0 + 0.0225 * n))
	# Returning the square root ensures that dE00 accurately reflects the
	# geometric distance in color space, which can range from 0 to around 185.
	return sqrt(l * l + h * h + c * c + c * h * r_t)
end

# GitHub Project : https://github.com/michel-leonard/ciede2000-color-matching
#   Online Tests : https://michel-leonard.github.io/ciede2000-color-matching

# L1 = 84.6   a1 = 56.7   b1 = -2.3
# L2 = 84.1   a2 = 62.9   b2 = 2.7
# CIE ΔE00 = 2.8540748739 (Bruce Lindbloom, Netflix’s VMAF, ...)
# CIE ΔE00 = 2.8540880501 (Gaurav Sharma, OpenJDK, ...)
# Deviation between implementations ≈ 1.3e-5

# See the source code comments for easy switching between these two widely used ΔE*00 implementation variants.

Parametri k_l, k_c e k_h

I parametri k_l, k_c e k_h nella formula CIEDE2000 sono fattori di ponderazione applicati rispettivamente alle componenti di luminosità (ΔL*), croma (ΔC*) e tinta (ΔH*). Sono definiti come costanti nel codice sorgente. Nel codice sorgente sono definiti come costanti con un valore predefinito di 1, che corrisponde alle condizioni di osservazione standard stabilite dalla Commissione internazionale per l’illuminazione (CIE). In pratica, potrebbe essere necessario regolare questi coefficienti per riflettere condizioni specifiche: ad esempio, k_l = 2 viene talvolta utilizzato per dare maggior peso alle differenze di luminosità (un caso comune nell’industria tessile), mentre k_c o k_h possono essere ridotti per aumentare la tolleranza alle variazioni di saturazione o di tonalità. In sintesi, questi coefficienti oscillano solitamente tra 0,5 e 2, dove 1 è il valore più comune.

Precisione e affidabilità del codice sorgente

La differenza tra la formulazione accademica di Sharma e quella semplificata di Lindbloom non supera ±0,0003 sul ΔE2000 finale. L’implementazione qui presentata è a 64 bit e garantisce una precisione superiore a 10 cifre decimali; la scelta di una formulazione piuttosto che un’altra è, quindi, un dettaglio tecnico. Nella parte superiore della pagina è possibile scegliere tra le due formulazioni; quella attualmente visualizzata è la formulazione semplificata.

Come si può stabilire se una determinata implementazione di CIEDE2000 è accademica o semplificata?

• Valutate ciede_2000(79.6,104.7,23.3,63.4,65.1,-14.3) con precisione
• Se il risultato è 20.00002, si tratta del tipo accademico (come Sharma, OpenJDK, ecc.)
• Se il risultato è 19.99997, si tratta del tipo semplificato (come Lindbloom, Netflix VMAF, ecc.)

Come si convertono i colori RGB in L*a*b*?

Andate alla pagina AWK, C, Dart, Java, JavaScript, Kotlin, Lua, PHP, Python, Ruby o Rust dove tale convertitore (che utilizza l’illuminante D65) è già implementato in aggiunta alla funzione di confronto dei colori.

Intervalli di valori in CIELAB e interpretazione del ΔE2000

Nello spazio colore CIELAB, la componente L* rappresenta la luminosità e varia tipicamente da 0 (nero) a 100 (bianco). Le componenti a* e b* definiscono gli assi cromatici: a* va dal verde al rosso, mentre b* va dal blu al giallo. In pratica, i valori di a* e b* sono quasi sempre compresi in un intervallo compreso tra -128 e +127, sebbene lo standard non specifichi un limite ufficiale per queste due componenti.

ΔE2000 (CIEDE2000) misura la differenza percepita tra due colori: 0 significa colori identici, e valori più alti (fino a 185 e oltre) indicano una differenza più evidente. Per esempio, un ΔE2000 intorno a 5 indica colori vicini, mentre intorno a 15 indica colori chiaramente distinti. Quando il valore ΔE2000 supera 40, i colori confrontati non hanno praticamente più nulla in comune e non è più possibile ricavarne informazioni precise.

Esempio di utilizzo in Julia

# Compute the Delta E (CIEDE2000) color difference between two L*a*b* colors in Julia

# Color 1 (L1, a1, b1)
l1, a1, b1 = 74.5, 29.6, 3.4

# Color 2 (L2, a2, b2)
l2, a2, b2 = 74.6, 35.1, -3.2

deltaE = ciede_2000(l1, a1, b1, l2, a2, b2)
println(deltaE)

# .................................................. This shows a ΔE2000 of 4.5852748113
# As explained in the comments, compliance with Gaurav Sharma would display 4.5852593642

I risultati dei test

Il nostro programma di test, scritto in C99, comprende 250 test statici accurati. I risultati dimostrano che questa funzione di CIEDE2000 in Julia è interoperabile con gli altri 41 linguaggi di programmazione.

CIEDE2000 Verification Summary :
  First Verified Line : 25.11,-80,77,2,26.08,-46,59.590330238040835
             Duration : 76.37 s
            Successes : 10000000
               Errors : 0
      Average Delta E : 62.9504
    Average Deviation : 5.0239383043038796e-15
    Maximum Deviation : 2.4158453015843406e-13

File da scaricare

Un file qui sotto supporta i calcoli di precisione arbitraria in Julia (utile se si ha a che fare con il ΔE2000 in metrologia). Sentitevi liberi di utilizzare questi file messi a disposizione da Michel, anche per scopi commerciali.

Comunità

Cosa ne pensate di questo codice sorgente o di CIEDE2000? La vostra opinione è importante per noi! Il libro degli ospiti contiene già 9 messaggi, di cui 1 in italiano. Date un’occhiata e condividete la vostra opinione.